UDF > GUI > GuiComboBoxEx >

_GUICtrlComboBoxEx_SetMinVisible

Définit le nombre minimum d'éléments visibles dans la liste déroulante d'une ComboBox

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetMinVisible ( $hWnd, $iMinimum )

Paramètres

$hWnd Handle du contrôle
$iMinimum Nombre minimum d'éléments visibles

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarques

Lorsque le nombre d'éléments dans la liste déroulante est supérieur au minimum, la ComboBox utilise une barre de défilement. Par défaut, 30 est le nombre minimum d'éléments visibles.

Ce message est ignorée si le contrôle ComboBox a le style $CBS_NOINTEGRALHEIGHT.

En relation

_GUICtrlComboBoxEx_GetMinVisible

Exemple

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGUI, $hImage, $iImage, $hCombo

    ; Crée une GUI
    $hGUI = GUICreate("ComboBoxEx Set Min Visible", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
    GUISetState(@SW_SHOW)

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

    _GUICtrlComboBoxEx_InitStorage($hCombo, 150, 300)
    _GUICtrlComboBoxEx_BeginUpdate($hCombo)

    For $x = 0 To 149
        $iImage = Random(0, 8, 1)
        _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)), $iImage, $iImage)
    Next
    _GUICtrlComboBoxEx_EndUpdate($hCombo)

    MsgBox($MB_SYSTEMMODAL, "Information", "Min Vis.: " & _GUICtrlComboBoxEx_GetMinVisible($hCombo))
    MsgBox($MB_SYSTEMMODAL, "Information", "Set Min Vis: " & _GUICtrlComboBoxEx_SetMinVisible($hCombo, 50))
    MsgBox($MB_SYSTEMMODAL, "Information", "Min Vis.: " & _GUICtrlComboBoxEx_GetMinVisible($hCombo))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example