UDF > GUI > GuiButton >

_GUICtrlButton_GetNoteLength

Obtient la longueur du texte de la note qui peut être affiché dans la description d'un bouton de commande de lien

#include <GuiButton.au3>
_GUICtrlButton_GetNoteLength ( $hWnd )

Paramètre

$hWnd ID/Handle du contrôle

Valeur de retour

Succès: Retourne la longueur du texte de la note dans WCHARs - non compris la terminaison NULL WCHAR.
Échec: Retourne 0.

Remarques

Cette fonction fonctionne uniquement avec les styles de bouton $BS_COMMANDLINK et $BS_DEFCOMMANDLINK.

Windows Vista ou une version ultérieure.

En relation

_GUICtrlButton_GetNote, _GUICtrlButton_SetNote

Voir aussi

Consultez BCM_GETNOTELENGTH dans la librairie MSDN.

Exemple

#include <GuiButton.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

; Notez que le handle de ces boutons ne peuvent pas être lu avec GUICtrlRead

Example()

Func Example()
    Local $hGUI

    $hGUI = GUICreate("Buttons", 400, 400)
    $g_idMemo = GUICtrlCreateEdit("", 10, 65, 390, 325, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")

    Local $hBtn = _GUICtrlButton_Create($hGUI, "Button1", 10, 10, 160, 40, BitOR($BS_COMMANDLINK, $BS_DEFPUSHBUTTON, $BS_PUSHLIKE))
    _GUICtrlButton_SetNote($hBtn, "Ceci est un test de Vista")

    GUISetState(@SW_SHOW)

    MemoWrite("Note: " & _GUICtrlButton_GetNote($hBtn))
    MemoWrite("Longueur de la Note: " & _GUICtrlButton_GetNoteLength($hBtn))
    MemoWrite("Texte du bouton: " & _GUICtrlButton_GetText($hBtn))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Écrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite