UDF > GUI > GuiButton >

_GUICtrlButton_GetNote

Obtient le texte de la note associée à un bouton de commande de lien

#include <GuiButton.au3>
_GUICtrlButton_GetNote ( $hWnd )

Paramètre

$hWnd ID/handle du contrôle

Valeur de retour

Succès: Retourne le texte associé au bouton de commande de lien.
Échec: Retourne une chaîne vide.

Remarques

Cette fonction fonctionne uniquement avec les styles de bouton $BS_COMMANDLINK et $BS_DEFCOMMANDLINK.

Windows Vista ou une version ultérieure.

En relation

_GUICtrlButton_GetNoteLength, _GUICtrlButton_SetNote

Voir aussi

Consultez BCM_GETNOTE dans la librairie MSDN.

Exemple

#include <GuiButton.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

; Notez que le controlID de ce bouton ne peut pas être lu avec GUICtrlRead.

Example()

Func Example()
    Local $hButton, $hGUI

    $hGUI = GUICreate("Buttons", 400, 400)
    $g_idMemo = GUICtrlCreateEdit("", 10, 75, 390, 315, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")

    $hButton = _GUICtrlButton_Create($hGUI, "Button1", 10, 10, 160, 60, BitOR($BS_COMMANDLINK, $BS_DEFCOMMANDLINK))
    _GUICtrlButton_SetNote($hButton, "This is a test of Vista")

    GUISetState(@SW_SHOW)

    MemoWrite("Note: " & _GUICtrlButton_GetNote($hButton))
    MemoWrite("Note Length: " & _GUICtrlButton_GetNoteLength($hButton))
    MemoWrite("Button Text: " & _GUICtrlButton_GetText($hButton))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Écrit une ligne dans le contrôle mémo.
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite