UDF > GDIPlus > PathGradientBrush >

_GDIPlus_PathBrushSetWrapMode

Définit le mode d'habillage d'un objet PathGradientBrush

#include <GDIPlus.au3>
_GDIPlus_PathBrushSetWrapMode ( $hPathGradientBrush, $iWrapMode )

Paramètres

$hPathGradientBrush Handle de l'objet PathGradientBrush
$iWrapMode Le mode Wrap spécifie comment une zone est pavée quand elle est peinte:
    0 - Disposition du dégradé en mosaïque, sans retournement
    1 - Retournement horizontal du dégradé, puis disposition en mosaïque
    2 - Retournement vertical du dégradé, puis disposition en mosaïque
    3 - Retournement horizontal et vertical du dégradé , puis disposition en mosaïque

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0, @extended contient le code erreur ($GPID_ERR*).

En relation

_GDIPlus_PathBrushGetWrapMode

Voir aussi

Consultez GdipSetPathGradientWrapMode dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGUI = GUICreate("GDI+", 600, 400)
    GUISetState(@SW_SHOW)

    _GDIPlus_Startup()
    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    _GDIPlus_GraphicsSetSmoothingMode($hGraphics, $GDIP_SMOOTHINGMODE_HIGHQUALITY)
    _GDIPlus_GraphicsClear($hGraphics, 0xFF000000)

    Local $aPoints[4][2] = [[3]]
    $aPoints[1][0] = 0
    $aPoints[1][1] = 0
    $aPoints[2][0] = 100
    $aPoints[2][1] = 30
    $aPoints[3][0] = 50
    $aPoints[3][1] = 80

    Local $hBrush = _GDIPlus_PathBrushCreate($aPoints, 3)
    _GDIPlus_PathBrushSetWrapMode($hBrush, 0)
    _GDIPlus_PathBrushSetCenterColor($hBrush, 0xFFFFFFFF)

    Local $aColors[4] = [3]
    $aColors[1] = 0xFFFF0000
    $aColors[2] = 0xFF00FF00
    $aColors[3] = 0xFF0000FF
    _GDIPlus_PathBrushSetSurroundColorsWithCount($hBrush, $aColors)

    _GDIPlus_GraphicsFillRect($hGraphics, 0, 0, 600, 400, $hBrush)

    Local $iWrapMode = _GDIPlus_PathBrushGetPointCount($hBrush), $sWarpMode
    Switch $iWrapMode
        Case 0
            $sWarpMode = "Pavage sans retournement"
        Case 1
            $sWarpMode = "Les pavés sont retournés horizontalement lorsque vous passez d'un pavé à l'autre sur une ligne"
        Case 2
            $sWarpMode = "Les pavés sont retournés verticalement lorsque vous passez d'un pavé à l'autre sur une colonne"
        Case 3
            $sWarpMode = "Les pavés sont retournés horizontalement lorsque vous passez d'un pavé à l'autre sur une ligne  et retournés verticalement lorsque vous passez d'un pavé à l'autre sur une colonne"
        Case 4
            $sWarpMode = "Aucun pavage n'a lieu"
    EndSwitch

    MsgBox($MB_SYSTEMMODAL, "", "Mode Wrap: " & $sWarpMode)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example