UDF > GDIPlus > PathGradientBrush >

_GDIPlus_PathBrushCreate

Crée un objet PathGradientBrush, pinceau à couleurs dégradées de tracé qui remplit l'intérieur d'un objet GraphicsPath, à partir d'un tableau de points et d'un mode d'habillage

#include <GDIPlus.au3>
_GDIPlus_PathBrushCreate ( $aPoints [, $iWrapMode = 0] )

Paramètres

$aPoints Tableau de points qui spécifie la limite du tracé du pinceau
    [0][0] - Nombre de points
    [1][0] - Point 1, position X
    [1][1] - Point 1, position Y
    [2][0] - Point 2, position X
    [2][1] - Point 2, position Y
    [n][0] - Point n, position X
    [n][1] - Point n, position Y
$iWrapMode [optionnel] Indique comment un dégradé est disposé en mosaïque lorsqu'il est plus petit que la zone à remplir:
    0 - Dispose le dégradé en mosaïque, sans symétrie
    1 - Retourne le dégradé horizontalement, puis le dispose en mosaïque
    2 - Retourne le dégradé verticalement, puis le dispose en mosaïque
    3 - Retourne le dégradé horizontalement et verticalement, puis le dispose en mosaïque
    4 - Le dégradé n'est pas disposé en mosaïque

Valeur de retour

Succès: Retourne le handle du nouvel objet PathGradientBrush.
Échec: Retourne 0 et définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

Remarques

Le dégradé de couleurs est un ombrage de couleurs unies allant du point central du tracé à son bord extérieur. Les facteurs de mélange, les positions et le style affectent les couleurs de début et de fin du dégradé ainsi que la vitesse à laquelle la couleur change.
Les pinceaux à couleurs dégradées de tracé sont insensibles au mode de lissage (SmoothingMode).
Lorsque vous en avez terminé avec l'objet, appelez _GDIPlus_BrushDispose() pour libérer les ressources de l'objet.

En relation

_GDIPlus_BrushDispose

Voir aussi

Consultez GdipCreatePathGradient dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI = GUICreate("GDI+", 600, 400)
    GUISetState(@SW_SHOW)

    _GDIPlus_Startup()
    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    _GDIPlus_GraphicsSetSmoothingMode($hGraphics, $GDIP_SMOOTHINGMODE_HIGHQUALITY)
    _GDIPlus_GraphicsClear($hGraphics, 0xFF000000)

    Local $aPoints[4][2] = [[3]]
    $aPoints[1][0] = 0
    $aPoints[1][1] = 0
    $aPoints[2][0] = 100
    $aPoints[2][1] = 30
    $aPoints[3][0] = 50
    $aPoints[3][1] = 80

    Local $hBrush = _GDIPlus_PathBrushCreate($aPoints, 3)
    _GDIPlus_PathBrushSetCenterColor($hBrush, 0xFFFFFFFF)

    Local $aColors[4] = [3]
    $aColors[1] = 0xFFFF0000
    $aColors[2] = 0xFF00FF00
    $aColors[3] = 0xFF0000FF
    _GDIPlus_PathBrushSetSurroundColorsWithCount($hBrush, $aColors)

    _GDIPlus_GraphicsFillRect($hGraphics, 0, 0, 600, 400, $hBrush)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example