UDF > GDIPlus > PathGradientBrush >

_GDIPlus_PathBrushSetPresetBlend

Définit les couleurs à mélanger et les positions correspondantes d'un pinceau à couleurs dégradées de tracé

#include <GDIPlus.au3>
_GDIPlus_PathBrushSetPresetBlend ( $hPathGradientBrush, $aInterpolations )

Paramètres

$hPathGradientBrush Handle de l'objet PathGradientBrush
$aInterpolations Tableau de couleurs à mélanger et positions correspondantes:
    [0][0] - Le nombre de paires (couleur,position), doit être d'au moins 2
    [1][0] - Couleur 1
    [1][1] - Position 1
    [2][0] - Couleur 2
    [2][1] - Position 2
    [n][0] - Couleur n
    [n][1] - Position n

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0, @extended contient le code erreur ($GPID_ERR*).

Remarque

Dans le paramètre $aInterpolations les éléments Couleur sont les codes des couleurs à fusionner et les éléments Position sont des pourcentages (/100) à partir de la ligne de début.

Voir aussi

Consultez GdipSetPathGradientPresetBlend dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI = GUICreate("GDI+", 200, 180)
    GUISetState(@SW_SHOW)

    _GDIPlus_Startup()
    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    _GDIPlus_GraphicsSetSmoothingMode($hGraphics, $GDIP_SMOOTHINGMODE_HIGHQUALITY)
    _GDIPlus_GraphicsClear($hGraphics, 0xFF000000)

    Local $hPath = _GDIPlus_PathCreate()
    _GDIPlus_PathAddEllipse($hPath, 10, 10, 180, 160)

    Local $hBrush = _GDIPlus_PathBrushCreateFromPath($hPath)
    _GDIPlus_PathBrushSetCenterPoint($hBrush, 100, 90)

    Local $aBlend[4][2] = [[3]]
    $aBlend[1][0] = 0xFFFF0000 ; rouge
    $aBlend[1][1] = 0 ; position = frontière
    $aBlend[2][0] = 0xFF00FF00 ; vert
    $aBlend[2][1] = 0.7 ; 70% de la distance frontière-> point central
    $aBlend[3][0] = 0xFF0000FF ; bleu
    $aBlend[3][1] = 1 ; point central
    _GDIPlus_PathBrushSetPresetBlend($hBrush, $aBlend)

    Local $aRect = _GDIPlus_PathBrushGetRect($hBrush)
    _GDIPlus_GraphicsFillRect($hGraphics, $aRect[0], $aRect[1], $aRect[2], $aRect[3], $hBrush)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_PathDispose($hPath)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example