UDF > GDIPlus > PathGradientBrush >

_GDIPlus_PathBrushGetRect

Obtient le plus petit rectangle qui entoure la frontière du tracé d'un pinceau à couleurs dégradées de tracé

#include <GDIPlus.au3>
_GDIPlus_PathBrushGetRect ( $hPathGradientBrush )

Paramètre

$hPathGradientBrush Handle de l'objet PathGradientBrush

Valeur de retour

Succès: Retourne un tableau contenant les propriétés du rectangle:
    [0] - Coordonnée X du coin supérieur gauche du rectangle
    [1] - Coordonnée Y du coin supérieur gauche du rectangle
    [2] - Largeur du rectangle
    [3] - Hauteur du rectangle
Échec: Définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

Voir aussi

Consultez GdipGetPathGradientRect dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI = GUICreate("GDI+", 200, 180)
    GUISetState(@SW_SHOW)

    _GDIPlus_Startup()
    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    _GDIPlus_GraphicsSetSmoothingMode($hGraphics, $GDIP_SMOOTHINGMODE_HIGHQUALITY)
    _GDIPlus_GraphicsClear($hGraphics, 0xFF000000)

    Local $hPath = _GDIPlus_PathCreate()
    _GDIPlus_PathAddEllipse($hPath, 10, 10, 180, 160)

    Local $hBrush = _GDIPlus_PathBrushCreateFromPath($hPath)
    _GDIPlus_PathBrushSetCenterColor($hBrush, 0xFFFFFF00)
    _GDIPlus_PathBrushSetCenterPoint($hBrush, 90, 80)
    _GDIPlus_PathBrushSetSurroundColor($hBrush, 0xFF0000FF)

    _GDIPlus_PathBrushSetGammaCorrection($hBrush, True)

    Local $aRect = _GDIPlus_PathBrushGetRect($hBrush)
    _GDIPlus_GraphicsFillRect($hGraphics, $aRect[0], $aRect[1], $aRect[2], $aRect[3], $hBrush)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_PathDispose($hPath)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example