UDF > GDIPlus > GraphicsPath >

_GDIPlus_PathAddPie

Ajoute un secteur angulaire à une figure

#include <GDIPlus.au3>
_GDIPlus_PathAddPie ( $hPath, $nX, $nY, $nWidth, $nHeight, $fStartAngle, $fSweepAngle )

Paramètres

$hPath Handle de l'objet GraphicsPath
$nX La coordonnée X du coin supérieur gauche du rectangle qui délimite l'ellipse qui inclut le secteur angulaire
$nY La coordonnée Y du coin supérieur gauche du rectangle qui délimite l'ellipse qui inclut le secteur angulaire
$nWidth La largeur du rectangle qui délimite l'ellipse qui inclut le secteur angulaire
$nHeight La hauteur du rectangle qui délimite l'ellipse qui inclut le secteur angulaire
$fStartAngle L'angle, en degrés, entre l'axe X et le point de début de l'arc qui définit le secteur angulaire.
Une valeur positive indique une rotation dans le sens horaire.
$fSweepAngle L'angle, en degrés, entre les points de début et de fin de l'arc qui définit le secteur angulaire.
Une valeur positive indique une rotation dans le sens horaire.

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0, @extended contient le code erreur ($GPID_ERR*).

Voir aussi

Consultez GdipAddPathPie dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI, $hGraphic, $hBrush, $hPen, $hPen2, $hPath

    ; Crée une GUI
    $hGUI = GUICreate("GDI+", 400, 400)
    GUISetState(@SW_SHOW)

    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI) ; Crée un objet graphique à partir du handle de la fenêtre
    _GDIPlus_GraphicsSetSmoothingMode($hGraphic, $GDIP_SMOOTHINGMODE_HIGHQUALITY) ; Définit pour l'objet graphique la qualité de rendu antialiasing
    _GDIPlus_GraphicsClear($hGraphic, 0xFFFFFFFF)

    $hBrush = _GDIPlus_BrushCreateSolid(0x7F8800AA)
    $hPen = _GDIPlus_PenCreate(0xFF8800AA, 2)

    $hPath = _GDIPlus_PathCreate() ; Crée un objet path

    _GDIPlus_PathAddPie($hPath, 50, 50, 300, 300, 135, 270)
    _GDIPlus_PathAddPie($hPath, 50, 80, 300, 300, 45, 90)

    _GDIPlus_GraphicsFillPath($hGraphic, $hPath, $hBrush) ; Dessine le Path avec le handle Graphic (GUI)
    _GDIPlus_GraphicsDrawPath($hGraphic, $hPath, $hPen) ; Dessine le Path avec le handle Graphic (GUI)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_PathDispose($hPath)
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_PenDispose($hPen2)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example