UDF > GDIPlus > GraphicsPath >

_GDIPlus_PathAddArc

Ajoute un arc elliptique à la figure actuelle d'un tracé

#include <GDIPlus.au3>
_GDIPlus_PathAddArc ( $hPath, $nX, $nY, $nWidth, $nHeight, $fStartAngle, $fSweepAngle )

Paramètres

$hPath Handle de l'objet GraphicsPath
$nX Coordonnée X du coin supérieur gauche de l'ellipse qui contient l'arc
$nY Coordonnée Y du coin supérieur gauche de l'ellipse qui contient l'arc
$nWidth Largeur du rectangle de délimitation de l'ellipse qui contient l'arc
$nHeight Hauteur du rectangle de délimitation de l'ellipse qui contient l'arc
$fStartAngle L'angle, en degrés, entre l'axe X et le point de départ de l'arc
$fSweepAngle L'angle, en degrés, entre les points de début et de fin de l'arc

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0, @extended contient le code erreur ($GPID_ERR*).

Voir aussi

Consultez GdipAddPathArc dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI, $hGraphic, $hBrush, $hPen, $hPath

    ; Crée une GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState(@SW_SHOW)

    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI) ; Crée un objet graphique à partir du handle de la fenêtre
    _GDIPlus_GraphicsSetSmoothingMode($hGraphic, $GDIP_SMOOTHINGMODE_HIGHQUALITY) ; Définit pour l'objet graphique la qualité de rendu antialiasing
    _GDIPlus_GraphicsClear($hGraphic, 0xFFFFFFFF)

    $hBrush = _GDIPlus_BrushCreateSolid(0x7F8800AA)
    $hPen = _GDIPlus_PenCreate(0xFF8800AA, 2)

    $hPath = _GDIPlus_PathCreate() ; Crée un objet path

    _GDIPlus_PathAddArc($hPath, 50, 50, 100, 100, 180, 180)
    _GDIPlus_PathAddArc($hPath, 50, 150, 100, 100, 0, 180)
    _GDIPlus_PathCloseFigure($hPath) ; Connecte le dernier point de ARC2 au premier point de ARC1

    _GDIPlus_PathAddArc($hPath, 250, 50, 100, 100, 180, 180)
    _GDIPlus_PathCloseFigure($hPath) ; Ne connecte pas l'arc
    _GDIPlus_PathAddArc($hPath, 250, 150, 100, 100, 0, 180)
    _GDIPlus_PathCloseFigure($hPath) ; Connecte le dernier point de ARC2 au premier point de ARC2

    _GDIPlus_GraphicsFillPath($hGraphic, $hPath, $hBrush) ; Dessine le Path avec le handle Graphic (GUI)
    _GDIPlus_GraphicsDrawPath($hGraphic, $hPath, $hPen) ; Dessine le Path avec le handle Graphic (GUI)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_PathDispose($hPath)
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example