UDF > GDIPlus > Image >

_GDIPlus_ImageScale

Change les échelles horizontale et verticale d'une image

#include <GDIPlus.au3>
_GDIPlus_ImageScale ( $hImage, $iScaleW, $iScaleH [, $iInterpolationMode = $GDIP_INTERPOLATIONMODE_HIGHQUALITYBICUBIC] )

Paramètres

$hImage Handle de l'image
$iScaleW Une valeur à virgule flottante: échelle horizontale
$iScaleH Une valeur à virgule flottante: échelle verticale
$iInterpolationMode [optionnel] Une valeur entière: mode d'interpolation. Par défaut, $GDIP_INTERPOLATIONMODE_HIGHQUALITYBICUBIC.

Valeur de retour

Succès: Retourne le handle du nouvel objet Bitmap
Échec: Retourne 0 et définit @error <> 0.
@error: 1 - Impossible d'obtenir la largeur de l'image
2 - Impossible d'obtenir la hauteur de l'image
3 - Impossible de créer un nouveau bitmap
4 - Impossible de créer le contexte graphique
5 - Impossible de définir le mode d'interpolation sur le contexte graphique
6 - Impossible de copier l'image dans le bitmap mis à l'échelle

Remarque

Un facteur d'échelle supérieur à 1 signifie un agrandissement de l'image alors que plus petit que 1 signifie une diminution de la taille.

En relation

_GDIPlus_BitmapCreateFromScan0, _GDIPlus_GraphicsDrawImageRect, _GDIPlus_GraphicsSetInterpolationMode, _GDIPlus_ImageGetGraphicsContext

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <ScreenCapture.au3>
#include <WinAPIHObj.au3>

Example()

Func Example()
    _GDIPlus_Startup()
    Local Const $iW = @DesktopWidth / 4, $iH = @DesktopHeight / 4

    Local $hHBmp = _ScreenCapture_Capture("", 0, 0, $iW, $iH) ; Crée un bitmap GDI en capturant un seizième de bureau
    Local $hBitmap = _GDIPlus_BitmapCreateFromHBITMAP($hHBmp) ; Convertit le bitmap GDI en GDI+
    _WinAPI_DeleteObject($hHBmp) ; Libère la ressource du bitmap GDI car elle n'est plus utile

    Local $iScale = 2.75 ; 1.0 est sans redimensionnement
    Local $hBitmap_Scaled = _GDIPlus_ImageScale($hBitmap, $iScale, $iScale, $GDIP_INTERPOLATIONMODE_NEARESTNEIGHBOR) ; Image à l'échelle de 275% (agrandissement)

    Local $hGUI = GUICreate("GDI+ test", $iW * $iScale, $iH * $iScale, -1, -1) ; Crée une GUI de test pour afficher l'image redimensionnée
    GUISetState(@SW_SHOW)

    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI) ; Crée un objet Graphics à partir du handle de la fenêtre
    _GDIPlus_GraphicsDrawImage($hGraphics, $hBitmap_Scaled, 0, 0) ; Affiche l'image à l'échelle

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE 

    ; Nettoie les ressources
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_BitmapDispose($hBitmap_Scaled)
    _GDIPlus_Shutdown()
    GUIDelete($hGUI)
EndFunc   ;==>Example