UDF > GDIPlus > ImageAttributes >

_GDIPlus_ImageAttributesSetColorMatrix

Définit ou efface les matrices d'ajustement des couleurs - et de niveaux de gris - pour une catégorie déterminée

#include <GDIPlus.au3>
_GDIPlus_ImageAttributesSetColorMatrix ( $hImageAttributes [, $iColorAdjustType = 0 [, $bEnable = False [, $tClrMatrix = 0 [, $tGrayMatrix = 0 [, $iColorMatrixFlags = 0]]]]] )

Paramètres

$hImageAttributes Handle de l'objet ImageAttribute
$iColorAdjustType [optionnel] La catégorie pour laquelle les matrices d'ajustement des couleurs - et de niveaux de gris - sont définies ou effacés:
    0 - L'ajustement couleur ou niveaux de gris s'applique à toutes les catégories qui n'ont pas leurs propres paramètres de réglage
    1 - L'ajustement couleur ou niveaux de gris s'applique à des images bitmap
    2 - L'ajustement couleur ou niveaux de gris s'applique aux opérations de pinceau dans les métafichiers
    3 - L'ajustement couleur ou niveaux de gris s'applique aux opérations de crayon dans les métafichiers
    4 - L'ajustement couleur ou niveaux de gris s'applique au texte dessiné dans les métafichiers
$bEnable [optionnel] If True, the specified matrices (color, grayscale or both) adjustments for the specified
$tClrMatrix [optionnel] Structure $tagGDIPCOLORMATRIX qui spécifie une matrice d'ajustement des couleurs
$tGrayMatrix [optionnel] Structure $tagGDIPCOLORMATRIX qui spécifie une matrice d'ajustement en niveaux de gris
$iColorMatrixFlags [optionnel] Type d'image et de couleur qui seront concernée par les matrices d'ajustement:
    0 - Toutes les valeurs de couleur (y compris les gris) sont ajustées par la même matrice couleur d'ajustement
    1 - Les couleurs sont ajustées mais les nuances de gris ne sont pas ajustées.
    2 - Les couleurs sont ajustées par une matrice et les nuances de gris sont ajustées par une autre matrice

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0, @extended contient le code erreur ($GPID_ERR*).

En relation

$tagGDIPCOLORMATRIX, _GDIPlus_ColorMatrixCreate, _GDIPlus_ColorMatrixCreateGrayScale

Voir aussi

Consultez GdipSetImageAttributesColorMatrix dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <ScreenCapture.au3>
#include <WinAPIHObj.au3>

Example()

Func Example()
    _GDIPlus_Startup() ; Initialise GDI+
    Local Const $iWidth = 600, $iHeight = 600

    Local $hGUI = GUICreate("GDI+ example", $iWidth, $iHeight) ; Crée une fenêtre de test
    GUISetState(@SW_SHOW)

    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI) ; Crée un objet Graphics à partir du handle de la fenêtre
    Local $hIA = _GDIPlus_ImageAttributesCreate() ; Crée un objet ImageAttribute

    Local $tColorMatrix = _GDIPlus_ColorMatrixCreateTranslate(0.5, 0.5, 0.5) ; Crée la matrice de luminosité des couleurs

    _GDIPlus_ImageAttributesSetColorMatrix($hIA, 0, True, $tColorMatrix) ; Ajuste la luminosité de l'image à 50 % plus lumineux

    Local $hHBmp = _ScreenCapture_Capture("", 0, 0, $iWidth, $iHeight) ; Crée un bitmap GDI en capturant une région du bureau
    Local $hBitmap = _GDIPlus_BitmapCreateFromHBITMAP($hHBmp) ; Convertit le bitmap GDI en GDI+
    _WinAPI_DeleteObject($hHBmp) ; Libère la ressource du bitmap GDI car elle n'est plus utile

    _GDIPlus_GraphicsDrawImageRectRect($hGraphics, $hBitmap, 0, 0, $iWidth, $iHeight, 0, 0, $iWidth, $iHeight, $hIA) ; Dessine le bitmap tout en appliquant le réglage de la couleur

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources GDI+
    _GDIPlus_ImageAttributesDispose($hIA)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_Shutdown()
    GUIDelete($hGUI)
EndFunc   ;==>Example