UDF > GDIPlus > ImageAttributes >

_GDIPlus_ImageAttributesSetColorKeys

Définit ou efface la couleur clé (plage de transparence) pour une catégorie déterminée

#include <GDIPlus.au3>
_GDIPlus_ImageAttributesSetColorKeys ( $hImageAttributes [, $iColorAdjustType = 0 [, $bEnable = False [, $iARGBLow = 0 [, $iARGBHigh = 0]]]] )

Paramètres

$hImageAttributes Handle de l'objet ImageAttribute
$iColorAdjustType [optionnel] La catégorie pour laquelle la couleur clé doit être définie ou effacée:
    0 - Le réglage de la couleur s'applique à toutes les catégories qui n'ont pas leurs propres paramètres de réglage
    1 - Le réglage de la couleur s'applique à des images bitmap
    2 - Le réglage de la couleur s'applique aux opérations de pinceau dans les métafichiers
    3 - Le réglage de la couleur s'applique aux opérations de crayon dans les métafichiers
    4 - Le réglage de la couleur s'applique au texte dessiné dans les métafichiers
$bEnable [optionnel] Si Vrai, la plage de transparence pour la catégorie spécifiée est appliquée; autrement, transparence
$iARGBLow [optionnel] Composantes Alpha, Rouge, Vert et Bleu d'une couleur qui indique la valeur de la couleur clé la plus faible.
$iARGBHigh [optionnel] Composantes Alpha, Rouge, Vert et Bleu d'une couleur qui indique la valeur de la couleur clé la plus haute

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0, @extended contient le code erreur ($GPID_ERR*).

Remarque

Toute couleur qui a chacune de ses trois composantes (rouge, vert, bleu) entre les composantes correspondantes des couleurs clés haute et basse est transparente.

Voir aussi

Consultez GdipSetImageAttributesColorKeys dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <ScreenCapture.au3>
#include <WinAPIHObj.au3>

Example()

Func Example()
    _GDIPlus_Startup() ; Initialise GDI+
    Local Const $iWidth = 600, $iHeight = 600

    Local $hGUI = GUICreate("GDI+ example", $iWidth, $iHeight) ; Crée une fenêtre de test
    GUISetState(@SW_SHOW)

    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI) ; Crée un objet Graphics à partir du handle de la fenêtre
    Local $hIA = _GDIPlus_ImageAttributesCreate() ; Crée un objet ImageAttribute

    _GDIPlus_ImageAttributesSetColorKeys($hIA, 0, True, 0x00000000, 0x00F7F7F7) ; Définit une page de couleurs transparentes

    Local $hHBmp = _ScreenCapture_Capture("", 0, 0, $iWidth, $iHeight) ; Crée un bitmap GDI en capturant une région du bureau
    Local $hBitmap = _GDIPlus_BitmapCreateFromHBITMAP($hHBmp) ; Convertit le bitmap GDI en GDI+
    _WinAPI_DeleteObject($hHBmp) ; Libère la ressource du bitmap GDI car elle n'est plus utile

    _GDIPlus_GraphicsDrawImageRectRect($hGraphics, $hBitmap, 0, 0, $iWidth, $iHeight, 0, 0, $iWidth, $iHeight, $hIA) ; Dessine le bitmap tout en appliquant le réglage de la couleur

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources GDI+
    _GDIPlus_ImageAttributesDispose($hIA)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_Shutdown()
    GUIDelete($hGUI)
EndFunc   ;==>Example