UDF > GDIPlus > Bitmap >

_GDIPlus_BitmapCreateFromStream

Crée un objet Bitmap à partir d'une interface COM IStream

#include <GDIPlus.au3>
_GDIPlus_BitmapCreateFromStream ( $pStream )

Paramètre

$pStream Pointeur sur une instance de l'interface COM IStream

Valeur de retour

Succès: Retourne le handle du nouvel objet Bitmap.
Échec: Retourne 0 et définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

Remarques

Cette fonction est utile pour charger des images compressées (jpeg, png, gif, etc.) à partir de la mémoire ou des ressources.
Lorsque vous en avez terminé avec l'objet, appelez _GDIPlus_BitmapDispose() pour libérer les ressources de l'objet.

En relation

_GDIPlus_ImageDispose, _WinAPI_CreateStreamOnHGlobal

Voir aussi

Consultez GdipCreateBitmapFromStream dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <ScreenCapture.au3>
#include <WinAPICom.au3>
#include <WinAPIConv.au3>
#include <WinAPIHObj.au3>

Example()

Func Example()
    _GDIPlus_Startup()
    Local Const $iW = @DesktopWidth / 2, $iH = @DesktopHeight / 2
    Local $hGUI = GUICreate("GDI+ test", $iW, $iH, -1, -1)
    GUISetState(@SW_SHOW)

    Local $hHBmp = _ScreenCapture_Capture("", 0, 0, @DesktopWidth / 2, @DesktopHeight / 2) ; Crée un bitmap GDI en capturant un quart de bureau
    Local $hBitmap = _GDIPlus_BitmapCreateFromHBITMAP($hHBmp) ; Convertit le bitmap GDI en GDI+
    _WinAPI_DeleteObject($hHBmp) ; Libère la ressource du bitmap GDI car elle n'est plus utile

    Local $sImgCLSID = _GDIPlus_EncodersGetCLSID("jpg") ; Crée le CLSID pour un type JPG de fichier d'image
    Local $tGUID = _WinAPI_GUIDFromString($sImgCLSID) ; Convertit le GUID du CLSID sous forme binaire et retourne la structure $tagGUID
    Local $pEncoder = DllStructGetPtr($tGUID) ; Obtient le pointeur sur la structure $tagGUID
    Local $tParams = _GDIPlus_ParamInit(1) ; Initialise une liste de paramètres de l'encodeur et retourne la structure  $tagGDIPENCODERPARAMS
    Local $tData = DllStructCreate("int Quality") ; Crée la struct pour définir le degré de qualité JPG
    DllStructSetData($tData, "Quality", 10) ; Qualité 0-100 (0 : plus bas, 100 : le plus élevé)
    Local $pData = DllStructGetPtr($tData) ; Obtient le pointeur sur la struct de qualité
    _GDIPlus_ParamAdd($tParams, $GDIP_EPGQUALITY, 1, $GDIP_EPTLONG, $pData) ; Ajoute une valeur à la liste des paramètres de l'encodeur
    Local $pParams = DllStructGetPtr($tParams) ; Obtient le pointeur sur la liste des paramètres de l'encodeur
    Local $pStream = _WinAPI_CreateStreamOnHGlobal() ; Crée un flux
    _GDIPlus_ImageSaveToStream($hBitmap, $pStream, $pEncoder, $pParams) ; Enregistre l'image au format JPG dans la mémoire
    Local $hBitmapFromStream = _GDIPlus_BitmapCreateFromStream($pStream) ; Crée le bitmap à partir du flux (ici du JPG en mémoire)

    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI) ; Crée un objet Graphics à partir du handle de la fenêtre
    _GDIPlus_GraphicsDrawImage($hGraphics, $hBitmapFromStream, 0, 0) ; Affiche l'image en streaming

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_BitmapDispose($hBitmapFromStream)
    _GDIPlus_Shutdown()
    GUIDelete($hGUI)
EndFunc   ;==>Example