UDF > GDIPlus > GraphicsCoders >


_GDIPlus_ParamInit

Alloue une liste vide de paramètres d'un encodeur

#include <GDIPlus.au3>
_GDIPlus_ParamInit ( $iCount )

Paramètre

$iCount Le nombre total de $tagGDIPENCODERPARAM que la liste peut contenir

Valeur de retour

Succès: Retourne une structure $tagGDIPENCODERPARAMS.
Échec: Définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

Remarque

Afin de passer des paramètres à l'une des fonctions de l'encodeur, vous devez utiliser une liste de paramètres de l'encodeur.
Cette fonction est utilisée pour attribuer une liste de paramètres à l'encodeur qui peut ensuite être transmis à _GDIPlus_ParamAdd() pour les ajouter aux paramètres actuels.

En relation

$tagGDIPENCODERPARAM, $tagGDIPENCODERPARAMS, _GDIPlus_ParamAdd

Exemple

#include <GDIPlus.au3>
#include <ScreenCapture.au3>

Example()

Func Example()
    Local $hImage, $sCLSID, $tData, $tParams

    ; Capture l'écran
    _ScreenCapture_Capture(@MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; Initialise la bibliothèque GDI+
    _GDIPlus_Startup()

    ; Charge l'image
    $hImage = _GDIPlus_ImageLoadFromFile(@MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; Obtient le CLSID de l'encodeur JPEG
    $sCLSID = _GDIPlus_EncodersGetCLSID("JPG")

    ; Met en place des paramètres pour la rotation de 90 degrés
    $tData = DllStructCreate("int Data")
    DllStructSetData($tData, "Data", $GDIP_EVTTRANSFORMROTATE90)
    $tParams = _GDIPlus_ParamInit(1)
    _GDIPlus_ParamAdd($tParams, $GDIP_EPGTRANSFORMATION, 1, $GDIP_EPTLONG, DllStructGetPtr($tData, "Data"))

    ; Enregistre l'image pivotée
    _GDIPlus_ImageSaveToFileEx($hImage, @MyDocumentsDir & "\GDIPlus_Image2.jpg", $sCLSID, DllStructGetPtr($tParams))

    ; Arrête bibliothèque GDI+
    _GDIPlus_Shutdown()

    ShellExecute(@MyDocumentsDir & "\GDIPlus_Image2.jpg")
EndFunc   ;==>Example