UDF > Date >

_Date_Time_TzSpecificLocalTimeToSystemTime

Convertit une heure locale en une heure UTC

#include <Date.au3>
_Date_Time_TzSpecificLocalTimeToSystemTime ( $tLocalTime [, $tTimeZone = 0] )

Paramètres

$tLocalTime Structure $tagSYSTEMTIME qui spécifie une heure locale ou un pointeur vers elle. La fonction convertit cette heure à l'heure UTC correspondante.
$tTimeZone [optionnel] Structure $tagTIME_ZONE_INFORMATION qui spécifie le fuseau horaire ou d'un pointeur vers elle.
Si 0, la fonction utilise le fuseau horaire actuellement actif.

Valeur de retour

Retourne une structure $tagSYSTEMTIME contenant l'heure en UTC.

En relation

$tagSYSTEMTIME, $tagTIME_ZONE_INFORMATION

Exemple

#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $tLocal, $tSystem

    ; Crée la GUI
    GUICreate("Temps", 400, 300)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Convertit une heure système en une heure locale
    $tSystem = _Date_Time_GetSystemTime()
    $tLocal = _Date_Time_SystemTimeToTzSpecificLocalTime($tSystem)
    MemoWrite("Heure système en heure locale . : " & _Date_Time_SystemTimeToDateTimeStr($tLocal))

    $tLocal = _Date_Time_GetLocalTime()
    $tSystem = _Date_Time_TzSpecificLocalTimeToSystemTime($tLocal)
    MemoWrite("Heure locale en heure système . : " & _Date_Time_SystemTimeToDateTimeStr($tSystem))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Écrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite