UDF > Date >

_Date_Time_DOSDateToArray

Décode une date DOS en un tableau

#include <Date.au3>
_Date_Time_DOSDateToArray ( $iDosDate )

Paramètres

$iDosDate Date MS-DOS, codée comme suit:
Bits 0-4 Jour du mois (1–31)
Bits 5-8 Mois (1 = janvier, 2 = février, et ainsi de suite)
Bits 9-15 Décalage de l'année par rapport à 1980 (ajoutez 1980 pour obtenir l'année actuelle)

Valeur de retour

Retourne un tableau (array) au format suivant:
[0] - Jour
[1] - Mois
[2] - Année

En relation

_Date_Time_DOSDateTimeToArray, _Date_Time_DOSTimeToArray

Exemple

#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $aDate

    ; Crée la GUI
    GUICreate("Temps", 400, 300)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Affiche la date FAT
    $aDate = _Date_Time_DOSDateToArray(0x3621) ; 01/01/2007
    MemoWrite("date FAT . : " & StringFormat("%02d/%02d/%04d", $aDate[0], $aDate[1], $aDate[2]))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Écrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite