UDF > Date >


_Date_Time_DOSDateTimeToArray

Décode une date/heure DOS dans un tableau

#include <Date.au3>
_Date_Time_DOSDateTimeToArray ( $iDosDate, $iDosTime )

Paramètres

$iDosDate Date MS-DOS, rempli comme suit:
Bits 0-4 Jour du mois (1–31)
Bits 5-8 Mois (1 = janvier, 2 = février, et ainsi de suite)
Bits 9-15 Décalage de l'année par rapport à 1980 (ajoutez 1980 pour obtenir l'année actuelle)
$iDosTime Date MS-DOS, rempli comme suit:
Bits 0-4 Seconde divisée par 2
Bits 5-10 Minute (0–59)
Bits 11-15 Heure (0–23 sur une horloge de 24 heures)

Valeur de retour

Retourne un tableau (array) au format suivant:
[0] - Mois
[1] - Jour
[2] - Année
[3] - Heure
[4] - Minute
[5] - Seconde

En relation

_Date_Time_DOSDateToArray, _Date_Time_DOSTimeToArray

Exemple

#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $aDate

    ; Crée la GUI
    GUICreate("Time", 400, 300)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Affiche la date/heure FAT
    $aDate = _Date_Time_DOSDateTimeToArray(0x3621, 0x944a) ; 01/01/2007 18:34:20
    MemoWrite("date FAT . : " & StringFormat("%02d/%02d/%04d", $aDate[0], $aDate[1], $aDate[2]))
    MemoWrite("time FAT . : " & StringFormat("%02d:%02d:%02d", $aDate[3], $aDate[4], $aDate[5]))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Écrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite