Functions > Window >


WinList

Obtient une liste de fenêtres.

WinList ( ["title" [, "text"]] )

Paramètres

title [optionnel] Le titre/hWnd/class des fenêtres à lister. Consultez Définition spéciale de titre.
text [optionnel] Le texte des fenêtres à lister. La valeur par défaut est une chaîne vide. Consultez Définition spéciale de texte.

Valeur de retour

Retourne un tableau correspondant aux titres et handles des fenêtres trouvées.

Remarques

Si aucun titre ou texte n'est donné, alors toutes les fenêtres de niveau supérieur sont retournées.
Le tableau retourné est un tableau à deux dimensions composé comme ceci:
    [0][0] = Nombre de fenêtres retournées
    [1][0] = Titre de la première fenêtre
    [1][1] = Handle de la première fenêtre (HWND)
    [2][0] = Titre de la deuxième fenêtre
    [2][1] = Handle de la deuxième fenêtre (HWND)
    ...
    [n][0] = Titre de la n-ième fenêtre
    [n][1] = Handle de la n-ième fenêtre (HWND)

En relation

WinGetHandle

Exemples

Exemple 1

#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Récupère une liste de handles de fenêtre.
    Local $aList = WinList()

    ; Boucle dans le tableau pour afficher uniquement les fenêtres visibles avec un titre.
    For $i = 1 To $aList[0][0]
        If $aList[$i][0] <> "" And BitAND(WinGetState($aList[$i][1]), 2) Then
            MsgBox($MB_SYSTEMMODAL, "", "Title: " & $aList[$i][0] & @CRLF & "Handle: " & $aList[$i][1])
        EndIf
    Next
EndFunc   ;==>Example


Exemple 2

#include <Array.au3>

Example()

Func Example()
    ; Récupère une liste de handles de fenêtre à l'aide d'une expression régulière.
    ; L'expression régulière recherche des titres qui contiennent le mot SciTE ou Internet Explorer.
    Local $aWinList = WinList("[REGEXPTITLE:(?i)(.*SciTE.*|.*Internet Explorer.*)]")
    _ArrayDisplay($aWinList)
EndFunc   ;==>Example