Functions > Tray >

TraySetIcon

Charge/Définit une icône donnée de la zone de notification.

TraySetIcon ( [filename [, iconID]] )

Paramètres

filename [optionnel] Le nom de l'icône à afficher dans la zone de notification.
iconID [optionnel] Identifiant de l'icône si le fichier contient plusieurs icônes.

Valeur de retour

Aucune.

Remarques

Pour définir l'icône par défaut, utilisez la fonction sans paramètre TraySetIcon().

Passez un nombre positif, pour faire référence à l'équivalent chaîne du nom de l'icône.
Passez un nombre négatif, pour obtenir un comportement d'«index» de base 1. Les icônes de certaines Dll peuvent être extraites seulement avec des nombres négatifs.

Le paramètre filename peut être "blank", "info", "question", "stop" ou "warning" afin de sélectionner l'icône standard correspondante.

En relation

TraySetPauseIcon, TraySetState

Exemple

#NoTrayIcon
#include <TrayConstants.au3> ; Pour la constante $TRAY_ICONSTATE_SHOW.

; Les items de menu, par défaut, ne seront pas affichés et 
; les items ne seront pas cochés lorsqu'ils seront sélectionnés. 
; Ce sont les options 1 et 2 de TrayMenuMode.
Opt("TrayMenuMode", 3)

Example()

Func Example()
    Local $idExit = TrayCreateItem("Exit")

    TraySetState($TRAY_ICONSTATE_SHOW) ; Affiche le menu de la zone de notification.

    Local $hTimer = TimerInit() ; Démarre un chrono et stocke Le handle dans une variable.
    Local $fDiff = 0, $iIndex = 0

    Do
        ; Temps écoulé depuis l'appel précédent de TimerInit 
        $fDiff = TimerDiff($hTimer)

        ; Si le temps écoulé est supérieure à 1 seconde, alors change l'icône du menu de la zone de notification.
        If $fDiff > 1000 Then
            ; Utilise un nombre négatif pour la numérotation ordinale. 
            $iIndex = -Random(0, 100, 1)

            ; Définit l'info-bulle du menu avec des informations sur l'index de l'icône.
            TraySetToolTip("Currently using the icon shell32.dll, " & $iIndex & ".")

            ; Définit l'icône du menu à l'aide de shell32.dll et d'un numéro aléatoire d'index.
            TraySetIcon("shell32.dll", $iIndex)

            ; Réinitialise le compteur.
            $hTimer = TimerInit()

        EndIf

    Until TrayGetMsg() = $idExit
EndFunc   ;==>Example