Functions > GUI > GUICtrlCreate >


GUICtrlCreateDummy

Crée un contrôle fictif -Dummy- dans la GUI.

GUICtrlCreateDummy ( )

Valeur de retour

Succès: Retourne l'identifiant du nouveau contrôle.
Échec: Retourne 0.

Remarque

Ce contrôle peut recevoir des messages grâce à un appel à GUICtrlSendToDummy. Le contrôle sera "notifié" comme un contrôle normal et la valeur envoyée avec GUISendToDummy pourra être lu avec GUICtrlRead().

En relation

GUICtrlRead, GUICtrlSendToDummy, GUICtrlSetData, GUICtrlSetOnEvent

Exemple

#include <GUIConstantsEx.au3>

Example()

Func Example()

    GUICreate("GUICtrlCreateDummy", 250, 200, 100, 200)
    GUISetBkColor(0x00E0FFFF) ; Change la couleur de fond

    Local $idUser = GUICtrlCreateDummy()
    Local $idButton = GUICtrlCreateButton("event", 75, 170, 70, 20)
    Local $idCancel = GUICtrlCreateButton("Cancel", 150, 170, 70, 20)
    GUISetState(@SW_SHOW)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Local $idMsg
    Do
        $idMsg = GUIGetMsg()

        Select
            Case $idMsg = $idButton
                GUICtrlSendToDummy($idUser)
            Case $idMsg = $idCancel
                GUICtrlSendToDummy($idUser)
            Case $idMsg = $idUser
                ; Action spéciale avant la fermeture
                ;...
                Exit
        EndSelect
    Until $idMsg = $GUI_EVENT_CLOSE
EndFunc   ;==>Example