[..] Barre de lancement rapide dans une icône de notification

[franco]

Bonjoir

Je vous explique d'abord le topo.


1. Je n'aime pas avoir des raccourcis, ni sur le bureau, ni sur la barre des tâches.
2. Oui, il existe la barre de lancement rapide... Mais personnellement, je n'aime pas l'aspect.
3. J'ai pas une grosse résolution d'écran.

J'ai donc testé des logiciels qui peuvent me permettre de lister des raccourcis dans une icône de notification.
Exemple : Quick Pop Menu (que j'utilise, SyMenu, etc...

Et là, j'ai eu un flash
Et pourquoi ne pas lister le dossier lié à la barre de lancement rapide. Bah oui, c'est juste un dossier...

Donc, dans l'optique, j'ai souhaité donc lister les raccourcis lnk dans une icône de notification.


Comme ceci :

Code: [Tout sélectionner] [Déplier/Replier]

$dossier_lr = @AppDataDir & '\Microsoft\Internet Explorer\Quick Launch'

#include <TrayConstants.au3>
#include <GUIConstantsEx.au3>
#include <ButtonConstants.au3>
#include <WindowsConstants.au3>


Opt("TrayMenuMode", 3)


$search = FileFindFirstFile($dossier_lr & "\*.lnk")

While 1
    $file = FileFindNextFile($search)
    If @error Then ExitLoop
   $item = TrayCreateItem( $file)
WEnd


TrayCreateItem("")
Local $SystrayEXIT = TrayCreateItem("Quitter")



While 1
   Switch TrayGetMsg()
      Case $SystrayEXIT
         Exit

      Case $item
         $choix = TrayItemGetText ( $item )
         MsgBox(0,'',$choix)

   EndSwitch
WEnd

GeSHi © Extension Codebox Plus

Je pensais juste afficher, dans un msgbox, l'intitulé de l'item choisi....

Mais que nenni, ça ne fonctionne pas comme ça....
Hélas, car sinon, je n'aurais pas besoin qu'on me guide.


Petite question : existe-t-il un moyen d'afficher, quand je clique sur un item quelconque, son beau petit texte ?


Merci d'avance.
Bonne journée (ou soirée, c'est selon )

[TommyDDR]

Cela fonctionne très bien chez moi.
Par contre, ça ne peut fonctionner qu'avec le dernier item de la liste car vous réaffectez la valeur de $item à chaque fois.

Voici la version en passant par un tableau :
-> J'ai ajouté un peu de rigueur en ajoutant "Opt("MustDeclareVars", 1)" qui lancera une erreur si vous utilisez des variables qui n'ont pas été explicitement déclarée (Local, Global, Dim) auparavant.

Code: [Tout sélectionner] [Déplier/Replier]

$dossier_lr = @AppDataDir & '\Microsoft\Internet Explorer\Quick Launch'

Opt("TrayMenuMode", 3)
Opt("MustDeclareVars", 1)

Global $search = FileFindFirstFile($dossier_lr & "\*.lnk")
Global $item[0]

While 1
    Local $file = FileFindNextFile($search)
    If @error Then ExitLoop
   Local $index = UBound($item, 1)
   ReDim $item[$index+1]
   $item[$index] = TrayCreateItem( $file)
WEnd

TrayCreateItem("")
Local $SystrayEXIT = TrayCreateItem("Quitter")

While 1
   Local $msg = TrayGetMsg()
   If($msg == $SystrayEXIT) Then
      Exit
   Else
      For $i = 0 To UBound($item, 1) - 1
         If($msg == $item[$i]) Then
            Local $choix = TrayItemGetText($item[$i])
            MsgBox(0,'',$choix)
            ExitLoop
         EndIf
      Next
   EndIf
WEnd

GeSHi © Extension Codebox Plus

J'en profite pour vous mettre la même version en mode évènementiel (activable avec : Opt("TrayOnEventMode", 1)), que je trouve beaucoup plus lisible et pratique que le mode par message.
Le mode consiste à gérer automatiquement l'association d'une fonction au clic sur un élément grâce aux fonctions TrayItemSetOnEvent et GUIOnEvent et GUICtrlOnEvent servant respectivement à gérer les éléments du tray, de la fenêtre (fermer, minimiser, restaurer, agrandir) et des controles.
Dans votre cas, seul celui concernant le tray est utile, et à l'intérieur de la fonction appelée vous avez accès à la macro @TRAY_ID qui contient l'id de l'élément (@GUI_CtrlId quand vous êtes dans une fonction appelé par un GUICtrlOnEvent).

Voici ce que ça donne :

Code: [Tout sélectionner] [Déplier/Replier]

$dossier_lr = @AppDataDir & '\Microsoft\Internet Explorer\Quick Launch'

Opt("TrayMenuMode", 3)
Opt("MustDeclareVars", 1)
Opt("GUIOnEventMode", 1)
Opt("TrayOnEventMode", 1)

Global $search = FileFindFirstFile($dossier_lr & "\*.lnk")
Global $item[0]

While 1
    Local $file = FileFindNextFile($search)
    If @error Then ExitLoop
   Local $index = UBound($item, 1)
   ReDim $item[$index+1]
   $item[$index] = TrayCreateItem( $file)
   TrayItemSetOnEvent($item[$index], clicLink)
WEnd
TrayCreateItem("")
Local $SystrayEXIT = TrayCreateItem("Quitter")
TrayItemSetOnEvent($SystrayEXIT, quit)

While 1
   Sleep(10)
WEnd

Func clicLink()
   For $i = 0 To UBound($item, 1) - 1
      If($item[$i] == @TRAY_ID) Then
         Local $choix = TrayItemGetText($item[$i])
         MsgBox(0,'',$choix)
      EndIf
   Next
EndFunc


Func quit()
   Exit
EndFunc

GeSHi © Extension Codebox Plus

[franco]

Lu'

Wow ! Un grand merci à toi...

Je peux encore t'embêter ?


En fait, je voulais mettre aussi des icônes pour chaque Item...
Et vu qu'il s'agit de raccourci, je sais comment trouver l'icône ( FileGetShortcut )


Je pensais - surement naïvement - que TraySetIcon pouvait le faire.
Mais bon, c'était trop simple, c'est juste pour l'icone du systray...

J'ai des recherches à faire, concernant cela...
J'ai trouvé surement des pistes, mais qui datent de 2008... ^^


Allez, zé parti


Encore merci.


PS : voici le script (bon, j'ai pas modifié grand chose)

Code: [Tout sélectionner] [Déplier/Replier]

$dossier_lr = @AppDataDir & '\Microsoft\Internet Explorer\Quick Launch'

Opt("TrayMenuMode", 3)
Opt("MustDeclareVars", 1)
Opt("GUIOnEventMode", 1)
Opt("TrayOnEventMode", 1)

Global $search = FileFindFirstFile($dossier_lr & "\*.lnk")
Global $item[0]

While 1
    Local $file = FileFindNextFile($search)
    If @error Then ExitLoop
        Local $index = UBound($item, 1)

        ReDim $item[$index+1]
        $item[$index] = TrayCreateItem( StringTrimRight($file,4))
        TrayItemSetOnEvent($item[$index], clicLink)
WEnd
TrayCreateItem("")
Local $SystrayEXIT = TrayCreateItem("Quitter")
TrayItemSetOnEvent($SystrayEXIT, quit)

While 1
        Sleep(10)
WEnd

Func clicLink()

        For $i = 0 To UBound($item, 1) - 1

                If($item[$i] == @TRAY_ID) Then
                        Local $choix = $dossier_lr & '\'&TrayItemGetText($item[$i])& '.lnk'
                        ShellExecute($choix)
            EndIf
           
      Next
     
EndFunc



Func quit()
        Exit
EndFunc

GeSHi © Extension Codebox Plus

++

[Eagle334]

Bonsoir,

Ce sujet pourrait t'intéresser je pense.

Création automatique de menu avec un fichier ini ou txt.

Un TrayMenu très bien conçu et pratique. Tu peux le modifier à ta guise car je l'ai moi même fait. (je l'ai modifié afin de pouvoir automatiser la création du MenuAuto.txt et j'ai aussi créé une GUI afin de mettre les raccourcis dans le traymenu, bon y'a des trucs que je comprends pas vraiment des fois mais je ne suis pas un as de la programmation.)

Merci à jl56 et zeshrek pour le lanceur!!!

PS: si tu le souhaites, je peux te montrer ce que j'ai fait.

[TommyDDR]

Je dois vous avouer que je n'ai jamais essayé de jouer avec les icones dans le tray.

Sinon, avez-vous entendu parler de Launchy ?
Il se présente sous cette forme :

launchy.png (27.06 Kio) Vu 2453 fois

Il est paramétrable en lui indiquant quels dossiers / extensions scanner.
Vous faites alt+espace (raccourci paramétrable), vous commencez à taper ce que vous voulez "scite" et il vous propose les programmes qu'il a trouvé.
Plus un programme est lancé via launchy, moins vous avez à écrire de lettres.
On peut même associer directement un mot clé à un fichier / url.

Vous l'aurez compris, je l'utilise tout le temps ^^

[Eagle334]

Jamais entendu parler...

Mais ça m'intéresse beaucoup, auriez-vous un lien pour pouvoir le récupérer?
Et si possible la source aussi, j'en demande peut-être un peu trop.

Merci d'avance.

[franco]

Salut.

En fait, je connais bien les "launcher". Launchy, Listary, etc...

Mais je voulais juste trouver une alternative à quick launch, la fameuse barre de lancement rapide.
Car je n'ai pas un pc fixe, mais un pc portable. Ce n'est donc pas une grosse résolution.

J'utilise pour ma part Quick Pop Menu (voire SyMenu).

Et j'aime bien avoir une barre de tâches vide, et avoir une icône de notification où je pourrais stocker mes raccourcis.


Bon, maintenant, j'ai fait divers tests, diverses, sur comment bien ( mieux ) exploiter le dossier du lancement rapide.
Car la fameuse barre de lancement rapide, c'est juste un dossier où on peut stocker divers raccourcis...


Donc, je me suis demandé :
1. Et si je pouvais afficher le dit dossier, mais incrusté dans une GUI ? ===> mes recherches m'ont données quoi faire.
2. Et si je pouvais rajouter - et adapté - le script que TommyDDR m'avait donné ==> c'est chose faite...

Bon, il y a encore une anomalie... Rien de bien grave (bien qu'agaçant mdr).



Je voulais donc "intégré" le contenu du dossier dans une interface => La recherche en FR n'a rien donnée, j'ai donc effectuée cette recherche en anglais...

Ma recherche : www.google.fr/search?q=autoit+embed+win ... rer+in+GUI
Ma trouvaille : https://www.autoitscript.com/forum/topi ... ent=427911
Mon script qui en découle :

► Afficher le texteSCRIPT

Code: [Tout sélectionner] [Déplier/Replier]

#include <GUIConstants.au3>
#include <IE.au3>
#include <Constants.au3>
#include <WinAPISysWin.au3>

Global $oIE

Opt("TrayMenuMode", 3)
Opt("TrayOnEventMode", 1)

Local $width = '345', $height = '395'

$dossier_lr = @AppDataDir & '\Microsoft\Internet Explorer\Quick Launch'

$int = GUICreate("Lancement rapide - Little Boy62", $width, $height, (@DesktopWidth - $width) - 10, (@DesktopHeight - $height) - 60, $WS_OVERLAPPEDWINDOW + $WS_CLIPSIBLINGS)
GUIRegisterMsg(0x0112, "OnSysCommand")
TraySetOnEvent($TRAY_EVENT_PRIMARYUP, "_Click")
;~ TraySetOnEvent($TRAY_EVENT_PRIMARYDOUBLE, "_quit")

$oIE = _IECreateEmbedded()
$GUIActiveX = GUICtrlCreateObj($oIE, 0, 0, 345, 395)

GUICtrlSetResizing(-1, $GUI_DOCKBORDERS)
_IENavigate($oIE, $dossier_lr, 0)


GUISetState(@SW_HIDE, $int) ;Show GUI

While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
      Case $GUI_EVENT_CLOSE
         _IntQuit()

      Case $GUI_EVENT_MINIMIZE
         GUISetState(@SW_HIDE, $int)


   EndSwitch
WEnd

Func _click()


   $state = WinGetState($int, "")

   If BitAND($state, 2) Then
      GUISetState(@SW_HIDE, $int)
   Else
      GUISetState(@SW_SHOW, $int)
   EndIf

EndFunc   ;==>_click

Func _quit()
   GUISetState(@SW_HIDE, $int)
   _IEQuit($oIE)
   Exit
EndFunc   ;==>_quit



Func _IntQuit()

;~ Global Const $WM_SYSCOMMAND = 0x0112
;~ Global Const $SC_MOVE = 0xF010
;~ Global Const $SC_SIZE = 0xF000
;~ Global Const $SC_CLOSE = 0xF060
;~ Global Const $SC_MAXIMIZE = 0xF030
;~ Global Const $SC_MINIMIZE = 0xF020


   Global $int_qt = GUICreate("", $width, 30, (@DesktopWidth - $width) - 2.5, (@DesktopHeight - $height) - 95, $WS_POPUP);, $WS_EX_LAYERED)
   GUISetBkColor(0xFFFFFF)
   GUISetFont(9, 500, 0, 'comic sans ms')

;~    GUISetBkColor(0xABCDEF)
;~    _WinAPI_SetLayeredWindowAttributes($int_qt, 0xABCDEF, 255)

   GUICtrlCreateLabel("Voulez-vous vraiment quitter ?", 5, 7.5, -1, 20)
   $Quitter = GUICtrlCreateButton('Oui.', 190, 5, 40, 20)
   $NePasQuitter = GUICtrlCreateButton('Non.', 240, 5, 40, 20)

   GUISetState(@SW_SHOW, $int_qt)
GUIRegisterMsg(0x0112, "OnSysCommand")

   While 1
      $nMsg = GUIGetMsg()
      Switch $nMsg
         Case $GUI_EVENT_CLOSE, $NePasQuitter
            GUIDelete($int_qt)
            ExitLoop
         Case $Quitter
            _IEQuit($oIE)
            Exit
         case $GUI_EVENT_MINIMIZE
            GUISetState(@SW_MINIMIZE, $int_qt)
      EndSwitch
   WEnd

EndFunc   ;==>_IntQuit



Func OnSysCommand($hWnd, $Msg, $wParam, $lParam)
    $test = BitAND($wParam, 0xFFF0)
    If $test = 0xF010  Then
    Return False
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc

GeSHi © Extension Codebox Plus

Maintenant, FUSION avec le script de départ (via le tray)
Script :

► Afficher le texteSCRIPT

Code: [Tout sélectionner] [Déplier/Replier]

#include <GUIConstants.au3>
#include <IE.au3>
#include <Constants.au3>
#include <WinAPISysWin.au3>

Global $oIE

Opt("TrayMenuMode", 3)
Opt("TrayOnEventMode", 1)

Local $width = '345', $height = '395'

$dossier_lr = @AppDataDir & '\Microsoft\Internet Explorer\Quick Launch'

$int = GUICreate("Lancement rapide - Little Boy62", $width, $height, (@DesktopWidth - $width) - 10, (@DesktopHeight - $height) - 60, $WS_OVERLAPPEDWINDOW + $WS_CLIPSIBLINGS)
GUIRegisterMsg(0x0112, "OnSysCommand")
TraySetOnEvent($TRAY_EVENT_PRIMARYDOUBLE, "_Click")
;~ TraySetOnEvent($TRAY_EVENT_PRIMARYDOUBLE, "_quit")

$oIE = _IECreateEmbedded()
$GUIActiveX = GUICtrlCreateObj($oIE, 0, 0, 345, 395)

GUICtrlSetResizing(-1, $GUI_DOCKBORDERS)
_IENavigate($oIE, $dossier_lr, 0)


GUISetState(@SW_HIDE, $int) ;Show GUI


Global $search = FileFindFirstFile($dossier_lr & "\*.lnk")
Global $item[0]

While 1
   Local $file = FileFindNextFile($search)
   If @error Then ExitLoop
   Local $index = UBound($item, 1)

   ReDim $item[$index + 1]
   $item[$index] = TrayCreateItem(StringTrimRight($file, 4))

   TrayItemSetOnEvent($item[$index], clicLink)
WEnd
TrayCreateItem("")
Local $SystrayEXIT = TrayCreateItem("Quitter")
TrayItemSetOnEvent($SystrayEXIT, quit)



While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
      Case $GUI_EVENT_CLOSE
         _IntQuit()

      Case $GUI_EVENT_MINIMIZE
         GUISetState(@SW_HIDE, $int)


   EndSwitch
WEnd

Func _click()

   $state = WinGetState($int, "")

   If BitAND($state, 2) Then
      GUISetState(@SW_HIDE, $int)
   Else
      GUISetState(@SW_SHOW, $int)
   EndIf

EndFunc   ;==>_click


func _systray()



   EndFunc

Func _quit()
   GUISetState(@SW_HIDE, $int)
   _IEQuit($oIE)
   Exit
EndFunc   ;==>_quit



Func _IntQuit()

;~ Global Const $WM_SYSCOMMAND = 0x0112
;~ Global Const $SC_MOVE = 0xF010
;~ Global Const $SC_SIZE = 0xF000
;~ Global Const $SC_CLOSE = 0xF060
;~ Global Const $SC_MAXIMIZE = 0xF030
;~ Global Const $SC_MINIMIZE = 0xF020


   Global $int_qt = GUICreate("", $width, 30, (@DesktopWidth - $width) - 2.5, (@DesktopHeight - $height) - 95, $WS_POPUP);, $WS_EX_LAYERED)
   GUISetBkColor(0xFFFFFF)
   GUISetFont(9, 500, 0, 'comic sans ms')

;~    GUISetBkColor(0xABCDEF)
;~    _WinAPI_SetLayeredWindowAttributes($int_qt, 0xABCDEF, 255)

   GUICtrlCreateLabel("Voulez-vous vraiment quitter ?", 5, 7.5, -1, 20)
   $Quitter = GUICtrlCreateButton('Oui.', 190, 5, 40, 20)
   $NePasQuitter = GUICtrlCreateButton('Non.', 240, 5, 40, 20)

   GUISetState(@SW_SHOW, $int_qt)
GUIRegisterMsg(0x0112, "OnSysCommand")

   While 1
      $nMsg = GUIGetMsg()
      Switch $nMsg
         Case $GUI_EVENT_CLOSE, $NePasQuitter
            GUIDelete($int_qt)
            ExitLoop
         Case $Quitter
            _IEQuit($oIE)
            Exit
         case $GUI_EVENT_MINIMIZE
            GUISetState(@SW_MINIMIZE, $int_qt)
      EndSwitch
   WEnd

EndFunc   ;==>_IntQuit



Func OnSysCommand($hWnd, $Msg, $wParam, $lParam)
    $test = BitAND($wParam, 0xFFF0)
    If $test = 0xF010  Then
    Return False
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc

Func clicLink()

   For $i = 0 To UBound($item, 1) - 1

      If ($item[$i] == @TRAY_ID) Then
         Local $choix = $dossier_lr & '\' & TrayItemGetText($item[$i]) & '.lnk'
         ShellExecute($choix)
      EndIf

   Next

EndFunc   ;==>clicLink

Func quit()
   Exit
EndFunc   ;==>quit

GeSHi © Extension Codebox Plus

Ce script, fonctionne en lui même...

Il y a juste un défaut.
Pour faire simple :
1. j'utilise le simple clic pour afficher les raccourcis dans l'icône de notification.
2. j'utilise le double clic pour m'afficher dans le "dossier" (via un _IECreateEmbedded) les raccourcis.

Le souci : quand je double clique, on voit d'abord le contenu de l'icône de notification, puis disparait, avoir d'avoir le "dossier".

Que faut-il faire pour le double clic n'affiche que la chose demandée ?


PS : j'ai aussi une erreur lié à IE quand j'essaye de quitter.

"C:\Program Files (x86)\AutoIt3\Include\IE.au3" (2604) : ==> The requested action with this object has failed.:
$oObject.quit()
$oObject^ ERROR

Vu que ça n'affecte pas le programme, peut-être que je devrais laisser tel quel.



Note :
Pour Launchy ce n'est pas codé en AutoIt.

Tu le trouveras ici : https://www.launchy.net

Et pour les fichiers (ini / txt), j'avais déjà vu ça.
Mais pour ce que je veux en faire, je m'en passerais.

Par contre, quand il s'agit de plus gros projets, avec un ini au poil, oui, ça fait le taf. ^^





Encore merci
++