Functions > Window >


WinGetState

Obtient l'état d'une fenêtre.

WinGetState ( "title" [, "text"] )

Paramètres

title Le titre/hWnd/class de la fenêtre à traiter. Consultez Définition spéciale de titre.
text [optionnel] Le texte de la fenêtre à traiter. La valeur par défaut est une chaîne vide. Consultez Définition spéciale de texte.

Valeur de retour

Succès: Retourne une valeur indiquant l'état de la fenêtre. Plusieurs valeurs peuvent être additionnées, donc utilisez BitAND() pour examiner la partie qui vous intéresse:
    $WIN_STATE_EXISTS (1) = La fenêtre existe
    $WIN_STATE_VISIBLE (2) = La fenêtre est visible
    $WIN_STATE_ENABLED (4) = La fenêtre est installée
    $WIN_STATE_ACTIVE (8) = La fenêtre est active
    $WIN_STATE_MINIMIZED (16) = La fenêtre est réduite
    $WIN_STATE_MAXIMIZED (32) = La fenêtre est agrandie
Échec: Retourne 0 et définit @error <> 0 si la fenêtre n'est pas trouvée.

Les constantes sont définies dans "AutoItConstants.au3".

En relation

BitAND, WinGetPos, WinSetState

Exemple

#include <AutoItConstants.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Exécute le Bloc-notes
    Run("notepad.exe")

    ; Attend 10 secondes pour que la fenêtre du bloc-notes apparaisse.
    Local $hWnd = WinWait("[CLASS:Notepad]", "", 10)

    ; Récupére l'état de la fenêtre du Bloc-notes en utilisant le handle retourné par WinWait.
    Local $iState = WinGetState($hWnd)

    ; Teste si la fenêtre du Bloc-notes est minimisée et affiche la boîte de message appropriée.
    If BitAND($iState, $WIN_STATE_MINIMIZED) Then
        MsgBox($MB_SYSTEMMODAL, "", "Notepad est minimisé et l'état retourné par WinGetState est - " & $iState)
    Else
        MsgBox($MB_SYSTEMMODAL, "", "Notepad n'est pas minimisé et l'état retourné par WinGetState est - " & $iState)
    EndIf

    ; Ferme la fenêtre du Bloc-notes en utilisant le handle retourné par WinWait.
    WinClose($hWnd)
EndFunc   ;==>Example