Functions > GUI > GUICtrlCreate >


GUICtrlCreateObj

Crée un contrôle ActiveX pour une GUI.

GUICtrlCreateObj ( ObjectVar, left, top [, width [, height]] )

Paramètres

ObjectVar Variable qui pointe sur un objet précédemment ouvert
left Coordonnée X du coin supérieur gauche du contrôle. Si -1 est utilisé, X sera calculée en accord avec GUICoordMode.
top Coordonnée Y du coin supérieur gauche du contrôle. Si -1 est utilisé, Y sera calculée en accord avec GUICoordMode.
width [optionnel] Largeur du contrôle (par défaut, la largeur utilisée précédemment ).
height [optionnel] Hauteur du contrôle (par défaut, la hauteur précédemment utilisée ).

Valeur de retour

Succès: Retourne l'ID du nouveau contrôle.
Échec: Retourne 0.

Remarques

Cette fonction tente d'intégrer un 'contrôle ActiveX' ou un 'Document Object' dans une GUI.
Pas tous les contrôles peuvent être intégrés. Ils doivent supporter au moins une interface 'IDispatch'.

Consultez Obj/COM Reference pour plus d'informations sur les objets.

'Document Objects' ne sera visible que si le style Windows $WS_CLIPCHILDREN a été utilisé dans GUICreate().

Les fonctions GUI GUICtrlRead() et GUICtrlSet n'ont aucun effet sur ce contrôle. L'objet ne peut être contrôlée qu'en utilisant des 'méthodes' ou 'propriétés' de l'objet $ObjectVar.

En relation

IsObj, ObjCreate, ObjEvent, ObjGet

Exemple

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Example()

; Exemple simple: Incorporation d'un objet Internet Explorer dans une GUI AutoIt
; Consultez aussi : http://msdn.microsoft.com/workshop/browser/webbrowser/reference/objects/internetexplorer.asp
Func Example()
    Local $idButton_Back, $idButton_Forward
    Local $idButton_Home, $idButton_Stop 

    Local $oIE = ObjCreate("Shell.Explorer.2")

    ; Crée une GUI simple pour notre résultat
    GUICreate("Embedded Web control Test", 640, 580, (@DesktopWidth - 640) / 2, (@DesktopHeight - 580) / 2, BitOR($WS_OVERLAPPEDWINDOW, $WS_CLIPSIBLINGS, $WS_CLIPCHILDREN))
    GUICtrlCreateObj($oIE, 10, 40, 600, 360)
    $idButton_Back = GUICtrlCreateButton("Back", 10, 420, 100, 30)
    $idButton_Forward = GUICtrlCreateButton("Forward", 120, 420, 100, 30)
    $idButton_Home = GUICtrlCreateButton("Home", 230, 420, 100, 30)
    $idButton_Stop = GUICtrlCreateButton("Stop", 330, 420, 100, 30)

    GUISetState(@SW_SHOW) ; Affiche l'interface utilisateur

    $oIE.navigate("http://www.autoitscript.com")

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Local $idMsg = GUIGetMsg()
    While $idMsg <> $GUI_EVENT_CLOSE
        Switch $idMsg
            Case $idButton_Home
                $oIE.navigate("http://www.autoitscript.com")
            Case $idButton_Back
                $oIE.GoBack
            Case $idButton_Forward
                $oIE.GoForward
            Case $idButton_Stop
                $oIE.Stop
        EndSwitch
        $idMsg = GUIGetMsg()
    WEnd

    GUIDelete()
EndFunc   ;==>Example