Functions > GUI > GUICtrlUpdate >


GUICtrlSetResizing

Définit la méthode de redimensionnement utilisée par un contrôle.

GUICtrlSetResizing ( controlID, resizing )

Paramètres

controlID L'identifiant du contrôle tel que retourné par une fonction GUICtrlCreate...(), ou -1 pour désigner le dernier contrôle créé.
resizing Voir la Tableau des valeurs d'Ancrage ci-dessous pour les valeurs qui peuvent être utilisées (additionner plusieurs valeurs si nécessaire).

Valeur de retour

Succès: Retourne 1.
Échec: Retourne 0.

Remarques

Quand une fenêtre GUI est redimensionnée, ses contrôles réagissent - la façon dont ils réagissent est déterminée par cette fonction. Pour être en mesure de redimensionner une fenêtre GUI, elle doit avoir été créée avec les styles $WS_SIZEBOX et $WS_SYSMENU. Consultez GUICreate().

    Tableau des valeurs d'Ancrage

Redimensionnement Valeur Aucun déplacement de
$GUI_DOCKAUTO 1 Redimensionne et repositionne en accord avec la nouvelle taille de la fenêtre
$GUI_DOCKLEFT 2 Coté gauche
$GUI_DOCKRIGHT 4 Coté droit
$GUI_DOCKHCENTER 8 La position ne se déplacera pas par rapport à l'axe central horizontal
$GUI_DOCKTOP 32 Coté supérieur
$GUI_DOCKBOTTOM 64 Coté inférieur
$GUI_DOCKVCENTER 128 La position ne se déplacera par rapport à l'axe central vertical
$GUI_DOCKWIDTH 256 La largeur ne changera pas
$GUI_DOCKHEIGHT 512 La hauteur ne changera pas
Redimensionnement composé
$GUI_DOCKSIZE 768 (256+512) La taille ne changera pas
$GUI_DOCKMENUBAR 544 (512+32) Donc le contrôle restera en haut de la fenêtre sans changement de hauteur
$GUI_DOCKSTATEBAR 576 (512+64) Donc le contrôle restera en bas de la fenêtre sans changement de hauteur
$GUI_DOCKALL 802 (2+32+256+512) Donc le contrôle ne se déplacera pas pendant le redimensionnement
$GUI_DOCKBORDERS 102 (2+4+32+64) Donc le contrôle va croître comme la fenêtre

La valeur par défaut de redimensionnement pour un contrôle donné dépend du contrôle, voir la documentation sur le contrôle.

L'événement de redimensionnement automatique peut être désactivé si GUIEventOptions (Option) est mis à 1.

En relation

GUICtrlCreate..., GUIEventOptions (Option), GUIResizeMode (Option)

Exemple

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Opt("GUICoordMode", 2)
    GUICreate("My InputBox", 190, 114, -1, -1, $WS_SIZEBOX + $WS_SYSMENU) ; commence la définition

    GUISetFont(8, -1, "Arial")

    GUICtrlCreateLabel("Prompt", 8, 7) ; ajoute des informations rapides
    GUICtrlSetResizing(-1, $GUI_DOCKLEFT + $GUI_DOCKTOP)

    Local $idEdit = GUICtrlCreateInput("Default", -1, 3, 175, 20, $ES_PASSWORD) ; ajoute une zone de saisie
    GUICtrlSetState($idEdit, $GUI_FOCUS)
    GUICtrlSetResizing($idEdit, $GUI_DOCKBOTTOM + $GUI_DOCKHEIGHT)

    Local $idOK = GUICtrlCreateButton("OK", -1, 3, 75, 24) ; ajoute un bouton qui fermera la GUI
    GUICtrlSetResizing($idOK, $GUI_DOCKBOTTOM + $GUI_DOCKSIZE + $GUI_DOCKHCENTER)

    Local $idCancel = GUICtrlCreateButton("Annuler", 25, -1) ; ajoute le bouton qui fermera la GUI
    GUICtrlSetResizing($idCancel, $GUI_DOCKBOTTOM + $GUI_DOCKSIZE + $GUI_DOCKHCENTER)

    GUISetState(@SW_SHOW) ;pour afficher l'interface graphique

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example