UDF > Word >

_Word_DocClose

Ferme le document Word spécifié

#include <Word.au3>
_Word_DocClose ( $oDoc [, $iSaveChanges = $WdDoNotSaveChanges [, $iOriginalFormat = $WdOriginalDocumentFormat]] )

Paramètres

$oDoc Objet document Word
$iSaveChanges [optionnel] Spécifie le mode d'enregistrement du document.
Peut être l'une des constantes suivantes de WdSaveOptions:
    $WdDoNotSaveChanges (option par défaut)
    $WdPromptToSaveChanges
    $WdSaveChanges
$iOriginalFormat [optionnel] Spécifie le format d'enregistrement du document.
Peut être l'une des constantes suivantes de WdOriginalFormat:
    $WdOriginalDocumentFormat (option par défaut)
    $WdPromptUser
    $WdWordDocument

Valeur de retour

Succès: Retourne 1.
Échec: Retourne 0 et définit @error <> 0.
@error: 1 - $oDoc n'est pas un objet
2 - Erreur retourné lors de la fermeture du document spécifié. @extended contient le code d'erreur COM

En relation

_Word_DocAdd, _Word_DocAttach, _Word_DocOpen

Exemple

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Crée un objet application
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocClose Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Ouvre un document test en lecture seule
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocClose Example", _
        "Error opening '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

;
; Ferme un document Word
;
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocClose Example", "Press 'OK' to close document '.\Extras\Test.doc'.")
_Word_DocClose($oDoc)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocClose Example", _
        "Error closing document '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocClose Example", "The document has been closed successfully.")