UDF > Word >

_Word_DocAdd

Ajoute un nouveau document vide à l'application Word spécifiée

#include <Word.au3>
_Word_DocAdd ( $oAppl [, $iDocumentType = $WdNewBlankDocument [, $sDocumentTemplate = "" [, $bNewTemplate = False]]] )

Paramètres

$oAppl Objet Word retourné par un appel précédent à _Word_Create()
$iDocumentType [optionnel] Peut être une des constantes de WdNewDocumentType suivantes:
    $WdNewBlankDocument (par défaut)
    $WdNewEmailMessage
    $WdNewFrameset
    $WdNewWebPage
$sDocumentTemplate [optionnel] Le nom du modèle à utiliser pour le nouveau document.
Si cet argument est omis, le modèle Normal est utilisé (par défaut = "")
$bNewTemplate [optionnel] True pour ouvrir le document comme un modèle (par défaut = False)

Valeur de retour

Succès: Retourne une variable pointant vers le nouvel objet document.
Échec: Retourne 0 et définit @error <> 0.
@error: 1 - $oAppl n'est pas un objet
2 - Le fichier du modèle spécifié n'existe pas
3 - Erreur retournée par la méthode Documents.Add. @extended contient le code d'erreur COM

En relation

_Word_DocClose, _Word_DocSave, _Word_DocSaveAs

Exemple

#include <MsgBoxConstants.au3>
#include <Word.au3>

Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocAdd Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

;
; Ajoute un nouveau document vide
;
_Word_DocAdd($oWord)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocAdd Example", "Error creating a new Word document." _
         & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocAdd Example", "A new empty document has successfully been added.")