UDF > Word >

_Word_DocAttach

Attache à la première instance d'un document Word, la recherche d'une chaîne dans le mode sélectionné

#include <Word.au3>
_Word_DocAttach ( $oAppl, $sString [, $sMode = "FilePath" [, $iCase = 0]] )

Paramètres

$oAppl Objet Word retourné par un appel précédent à _Word_Create()
$sString Chaîne à rechercher
$sMode [optionnel] Mode de recherche à utiliser. Les modes valides sont:
    "FileName" - nom du document ouvert
    "FilePath" - chemin complet vers le document ouvert (par défaut)
    "Text" - texte dans le corps du document
$iCase [optionnel] Spécifie la sensibilité à la casse de la fonction StringInStr() utilisée pour le mode de recherche "Text":
    0 - insensible à la casse, en utilisant la locale de l'utilisateur (par défaut)
    1 - sensible à la casse
    2 - insensible à la casse, en utilisant une comparaison de base/rapide

Valeur de retour

Succès: Retourne une variable pointant sur l'objet de document.
Échec: Retourne 0 et définit @error <> 0.
@error: 1 - $oAppl n'est pas un objet
2 - $sString est vide
3 - $sMode est invalide. Doit être "FilePath","FileName" ou "Text"
4 - La recherche a été infructueuse

Remarque

Cette fonction retourne seulement l'objet du document trouvé.
Pour accéder à l'application Word correspondante utilisez: $oAppl = $oDoc.Application.

En relation

_Word_DocClose, _Word_DocGet

Exemples

Exemple 1

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Crée un objet application
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocAttach Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Ouvre un document test en lecture seulement
_Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocAttach Example", "Error opening '.\Extras\Test.doc'." & _
        @CRLF & "@error = " & @error & ", @extended = " & @extended)

;
; Attache au document test par "FileName" et définit le focus dans la fenêtre
;
Local $oDoc = _Word_DocAttach($oWord, "Test.doc", "Filename")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocAttach Example", _
        "Error attaching to '.\Extras\Test.doc' by 'FileName'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Définit le focus dans le document Word - le paramètre $f_takeFocus de l'ancienne fonction _WordCreate
WinActivate($oWord.ActiveWindow.Caption & " - " & $oWord.Caption)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocAttach Example", "Attach to document by 'FileName' successfull!" & @CRLF & _
        @CRLF & "Text of the attached document:" & @CRLF & $oDoc.Range().Text)

Exemple 2

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Crée un objet application
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocAttach Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Ouvre un document test en lecture seulement
_Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocAttach Example", "Error opening '.\Extras\Test.doc'." & _
        @CRLF & "@error = " & @error & ", @extended = " & @extended)

;
; Attache au document test par "Text"
;
Local $oDoc = _Word_DocAttach($oWord, "Test", "Text")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocAttach Example", _
        "Error attaching to '\Extras\Test.doc' by 'Text'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocAttach Example", "Attach to document by 'Text' successfull!" & _
        @CRLF & @CRLF & "Text of the attached document:" & @CRLF & $oDoc.Range().Text)