UDF > Word >

_Word_DocGet

Retourne un objet collection contenant tous les documents ou un objet pour un document unique

#include <Word.au3>
_Word_DocGet ( $oAppl [, $vIndex = -1] )

Paramètres

$oAppl Objet Word retourné par un appel précédent à _Word_Create()
$vIndex [optionnel] Spécifie ce qu'il faut retourner:
   -1 - Retourne une collection de tous les documents (par défaut)
    0 - Retourne le document actif
    n - Le numéro d'index du document pour retourner (compté à partir de 1)
    x - Le nom du document à retourner

Valeur de retour

Succès: Retourne une variable pointant sur la collection des documents ou un objet document unique.
@extended contient le nombre total de documents
Échec: Retourne 0 et définit @error <> 0.
@error: 1 - $oAppl n'est pas un objet
2 - $vIndex est invalide (< -1 ou > Documents.Count)
3 - Le document spécifié n'a pas pu être trouvé ou erreur s'est produite. @extended contient le code d'erreur COM
4 - Erreur retournée lors de l'accès à la collection Documents. @extended contient le code d'erreur COM

En relation

_Word_DocAttach

Exemple

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Crée un objet application
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocGet Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Ouvre \Extras\test.doc en lecture seule
_Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocGet Example", "Error opening '.\Extras\Test.doc'." & @CRLF & _
        "@error = " & @error & ", @extended = " & @extended)
; Ouvre \Extras\test2.doc en lecture seule
_Word_DocOpen($oWord, @ScriptDir & "\Extras\Test2.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocGet Example", "Error opening '.\Extras\Test2.doc'." & @CRLF & _
        "@error = " & @error & ", @extended = " & @extended)

;
; Obtient le premier document de la collection, écrit le nom et le nombre total des documents
; dans la console.
;
Local $oDoc = _Word_DocGet($oWord, 1)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocGet Example", _
        "Error accessing collection of documents." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocGet Example", "First document in the document collection has been selected." & _
        @CRLF & "Name is: " & $oDoc.Name & @CRLF & "Total number of documents in the collection: " & @extended)