UDF > Word >

_Word_DocSaveAs

Enregistre le document Word spécifié avec un nom ou un format nouveau

#include <Word.au3>
_Word_DocSaveAs ( $oDoc [, $sFileName = Default [, $iFileFormat = $WdFormatDocument [, $bReadOnlyRecommended = False [, $bAddToRecentFiles = True [, $sPassword = "" [, $sWritePassword = ""]]]]]] )

Paramètres

$oDoc Objet document Word
$sFileName [optionnel] Le nom complet du document (par défaut = le dossier actuel et le nom du fichier en cours).
Si le document n'a jamais été enregistré, un nom par défaut est utilisé (par exemple, Doc1.doc)
$iFileFormat [optionnel] Le format dans lequel le document doit être enregistré.
Peut prendre toute valeur de wdSaveFormat (par défaut = $wdFormatDocument)
$bReadOnlyRecommended [optionnel] True pour que Word suggère le statut lecture seule chaque fois que le document est ouvert (par défaut = False)
$bAddToRecentFiles [optionnel] True pour ajouter le document à la liste des fichiers récemment utilisés (par défaut = True)
$sPassword [optionnel] Une chaîne mot de passe pour ouvrir le document (par défaut = "")
$sWritePassword [optionnel] Une chaîne mot de passe pour enregistrer les modifications au document (par défaut = "")

Valeur de retour

Succès: Retourne 1.
Échec: Retourne 0 et définit @error <> 0.
@error: 1 - $oDoc n'est pas un objet
2 - Une erreur s'est produite lors de l'enregistrement du document spécifié. @extended contient le code d'erreur COM

Remarque

Si un document avec le nom de fichier spécifié existe déjà, le document sera écrasé sans que l'utilisateur soit préalablement averti.

En relation

_Word_DocSave

Exemple

#include <FileConstants.au3>
#include <MsgBoxConstants.au3>
#include <Word.au3>

; Copie \Extras\Test.doc vers @TempDir
If FileCopy(@ScriptDir & "\Extras\Test.doc", @TempDir & "\_Word_Test.doc", $FC_OVERWRITE) = 0 Then Exit MsgBox($MB_SYSTEMMODAL, _
        "Word UDF: _Word_DocSaveAs Example", "Couldn't copy '.\Extras\Test.doc' as '_Word_Test.doc' to the @TempDir directory.")
; Crée un objet application
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocSaveAs Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Ouvre le document test
Local $oDoc = _Word_DocOpen($oWord, @TempDir & "\_Word_Test.doc")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocSaveAs Example", _
        "Error opening '_Word_Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

;
; Enregistre le document sous le nom _Word_Test2.doc
;
; Insert text at the beginning
Local $oRange = _Word_DocRangeSet($oDoc, -1)
$oRange.Text = "Bold text at the beginning. "
$oRange.Bold = True
; Enregistre le document
_Word_DocSaveAs($oDoc, @TempDir & "\_Word_Test2.doc")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocSaveAs Example", _
        "Error saving the Word document." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocSaveAs Example", "Document successfully saved as '" & _
        @TempDir & "\_Word_Test2.doc'.")