UDF > Sound >

_SoundStop

Arrête la lecture d'un son

#include <Sound.au3>
_SoundStop ( ByRef $aSndID )

Paramètre

$aSndID Tableau d'identification du son retourné par _SoundOpen() ou le nom du fichier (doit être une variable)

Valeur de retour

Succès: Retourne 1.
Échec: Retourne 0 et définit @error <> 0.
@error: 1 = Échec de la fonction
3 = ID du son invalide. Utiliser le tableau retourné par _SoundOpen() ou un nom de fichier valide.

Remarque

_SoundPlay() va rejouer le son depuis le début.

En relation

_SoundOpen, _SoundPlay

Exemple

#include <MsgBoxConstants.au3>
#include <Sound.au3>

Local $aSound = _SoundOpen(@WindowsDir & "\media\tada.wav")
If @error = 2 Then
    MsgBox($MB_SYSTEMMODAL, "Erreur", "Le fichier n'existe pas!")
    Exit
ElseIf @extended <> 0 Then
    Local $iExtended = @extended ; Parce que @extended sera redéfini après DllCall.
    Local $tText = DllStructCreate("char[128]")
    DllCall("winmm.dll", "short", "mciGetErrorStringA", "str", $iExtended, "ptr", DllStructGetPtr($tText), "int", 128)
    MsgBox($MB_SYSTEMMODAL, "Erreur", "L'ouverture a échoué." & @CRLF & "Numéro de l'erreur: " & $iExtended & @CRLF & "Description de l'erreur: " & DllStructGetData($tText, 1) & @CRLF & "Notez SVP: Le son peut toujours jouer correctement.")
Else
    MsgBox($MB_SYSTEMMODAL, "Succès", "L'ouverture du fichier a réussi.")
EndIf

_SoundPlay($aSound)

Do
    Sleep(100)
Until _SoundPos($aSound, 2) >= 1000

_SoundStop($aSound)

; Montre que le son commence au début après son arrêt.
_SoundPlay($aSound, 1)

_SoundClose($aSound)