UDF > Sound >

_SoundClose

Ferme un son préalablement ouvert avec _SoundOpen

#include <Sound.au3>
_SoundClose ( $aSndID )

Paramètre

$aSndID Tableau d'identification du son retourné par _SoundOpen()

Valeur de retour

Succès: Retourne 1.
Échec: Retourne 0 et définit @error <> 0.
@error: 1 = Échec
3 = ID du son invalide. Utiliser le tableau retourné par _SoundOpen().

En relation

_SoundOpen

Exemple

#include <MsgBoxConstants.au3>
#include <Sound.au3>

Local $aSound = _SoundOpen(@WindowsDir & "\media\tada.wav")
If @error = 2 Then
    MsgBox($MB_SYSTEMMODAL, "Erreur", "Le fichier n'existe pas.")
    Exit
ElseIf @extended <> 0 Then
    Local $iExtended = @extended ; Parce que @extended sera défini après DllCall.
    Local $tText = DllStructCreate("char[128]")
    DllCall("winmm.dll", "short", "mciGetErrorStringA", "str", $iExtended, "ptr", DllStructGetPtr($tText), "int", 128)
    MsgBox($MB_SYSTEMMODAL, "Erreur", "L'ouverture du fichier a échoué." & @CRLF & "Numéro de l'erreur: " & $iExtended & @CRLF & "Description de l'erreur: " & DllStructGetData($tText, 1) & @CRLF & "Notez SVP: Le son peut encore jouer correctement.")
Else
    MsgBox($MB_SYSTEMMODAL, "Succès", "Le fichier est ouvert avec succès.")
EndIf

If _SoundClose($aSound) Then
    MsgBox($MB_SYSTEMMODAL, "Succès", "Le son a été fermé avec succès.")
Else
    MsgBox($MB_SYSTEMMODAL, "Erreur", "La fermeture du fichier a échoué.")
EndIf