UDF > Sound >

_SoundStatus

Retourne le status du son

#include <Sound.au3>
_SoundStatus ( $aSndID )

Paramètre

$aSndID Tableau d'identification du son retourné par _SoundOpen() ou le nom du fichier

Valeur de retour

Succès: Retourne l'état solide.
Échec: 0 et @error <> 0.
@error: 3 ID = non valide Sound. Utiliser un tableau de retour _SoundOpen() ou un nom de fichier valide.

Remarque

De MSDN:
Tous les périphériques peuvent retourner les valeurs "pas prêt", "en pause", "en cours de lecture", et "arrêté".
Certains périphériques peuvent retourner de plus les valeurs "ouvert", "parqué", "enregistrement en cours", et "repositionnement".

En relation

_SoundOpen

Exemple

#include <MsgBoxConstants.au3>
#include <Sound.au3>

Local $aSound = _SoundOpen(@WindowsDir & "\media\tada.wav")
If @error = 2 Then
    MsgBox($MB_SYSTEMMODAL, "Error", "Le fichier n'existe pas!")
    Exit
ElseIf @extended <> 0 Then
    Local $iExtended = @extended ; Parce que @extended sera défini après DllCall.
    Local $tText = DllStructCreate("char[128]")
    DllCall("winmm.dll", "short", "mciGetErrorStringA", "str", $iExtended, "ptr", DllStructGetPtr($tText), "int", 128)
    MsgBox($MB_SYSTEMMODAL, "Error", "L'ouverture a échoué." & @CRLF & "Numéro de l'erreur: " & $iExtended & @CRLF & "Description de l'erreur: " & DllStructGetData($tText, 1) & @CRLF & "Notez SVP: Le son peut toujours jouer correctement.")
Else
    MsgBox($MB_SYSTEMMODAL, "Succès", "L'ouverture du fichier a réussi.")
EndIf

ConsoleWrite("Après _SoundOpen: " & _SoundStatus($aSound) & @CRLF)

_SoundPlay($aSound)
ConsoleWrite("Après _SoundPlay: " & _SoundStatus($aSound) & @CRLF)

Sleep(1000)

_SoundPause($aSound)
ConsoleWrite("Après _SoundPause: " & _SoundStatus($aSound) & @CRLF)

Sleep(1000)
_SoundResume($aSound)

Do
    Sleep(100)
Until _SoundPos($aSound, 2) = _SoundLength($aSound, 2)

_SoundClose($aSound)