UDF > NetShare >


_Net_Share_FileClose

Force une ressource à se fermer

#include <NetShare.au3>
_Net_Share_FileClose ( $sServer, $iFileID )

Paramètres

$sServer Indique le nom DNS ou NetBIOS du serveur distant sur lequel la fonction s'exécutera.
Si ce paramètre est vide, l'ordinateur local sera utilisé.
$iFileID Indique l'identifiant fichier de l'instance de ressource ouverte qu'il faut fermer

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarque

Seuls les membres Administrateurs ou du groupe local Server Operators peuvent exécuter cette fonction.

Voir aussi

Consultez NetFileClose dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <NetShare.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $sServer, $aInfo

    ; Crée une GUI
    GUICreate("NetShare", 400, 300)

    ; Crée un contrôle Memo
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Obtient le serveur et le nom de partage
    $sServer = InputBox("NetWork Demo", "Enter Server Name:", "\\MyServer", "", 200, 130)
    If @error Then Exit

    ; Énumére les fichiers ouverts sur le serveur
    $aInfo = _Net_Share_FileEnum($sServer)
    MemoWrite("Error ...................: " & @error)
    MemoWrite("Entries read ............: " & $aInfo[0][0])

    ; Force la fermeture d'un fichier ouvert nommé "Test.txt"
    For $iI = 1 To $aInfo[0][0]
        If StringInStr($aInfo[$iI][3], "Test.txt") > 0 Then
            _Net_Share_FileClose($sServer, $aInfo[$iI][0])
            MemoWrite("Fichier fermé")
        EndIf
    Next

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit un message dans le contrôle Memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite