UDF > GUI > GuiScrollBars >

_GUIScrollBars_SetScrollInfoMax

Définit la position maximale de défilement

#include <GuiScrollBars.au3>
_GUIScrollBars_SetScrollInfoMax ( $hWnd, $iBar, $iMax )

Paramètres

$hWnd Le handle de la fenêtre
$iBar Spécifie le type de barre de défilement. Ce paramètre peut prendre l'une des valeurs suivantes:
    $SB_CTL - Définit les paramètres pour un contrôle de barre de défilement. Le paramètre $hWnd doit être le handle du contrôle de la barre de défilement.
    $SB_HORZ - Définit les paramètres de la barre de défilement horizontale standard de la fenêtre.
    $SB_VERT - Définit les paramètres de la barre de défilement verticale standard de la fenêtre.
$iMax La position maximale de défilement

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUIScrollBars_SetScrollInfo, _GUIScrollBars_SetScrollRange

Exemple

#include <GUIConstantsEx.au3>
#include <GuiScrollBars.au3>
#include <StructureConstants.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI

    $hGUI = GUICreate("ScrollBar Example", 400, 400, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_SIZEBOX))
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 380, 380, BitOR($WS_HSCROLL, $WS_VSCROLL))
    GUICtrlSetResizing($g_idMemo, $GUI_DOCKALL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetBkColor(0x88AABB)

    GUISetState(@SW_SHOW)

    _GUIScrollBars_Init($hGUI)

    _GUIScrollBars_SetScrollInfoMin($hGUI, $SB_HORZ, 10)
    _GUIScrollBars_SetScrollInfoMax($hGUI, $SB_HORZ, 80)

    MemoWrite("Horizontal" & @CRLF & "--------------------------------------")
    MemoWrite("nPage....: " & _GUIScrollBars_GetScrollInfoPage($hGUI, $SB_HORZ))
    MemoWrite("nPos.....: " & _GUIScrollBars_GetScrollInfoPos($hGUI, $SB_HORZ))
    MemoWrite("nMin.....: " & _GUIScrollBars_GetScrollInfoMin($hGUI, $SB_HORZ))
    MemoWrite("nMax.....: " & _GUIScrollBars_GetScrollInfoMax($hGUI, $SB_HORZ))
    MemoWrite("nTrackPos: " & _GUIScrollBars_GetScrollInfoTrackPos($hGUI, $SB_HORZ))

    MemoWrite(@CRLF & "Vertical" & @CRLF & "--------------------------------------")
    MemoWrite("nPage....: " & _GUIScrollBars_GetScrollInfoPage($hGUI, $SB_VERT))
    MemoWrite("nPos.....: " & _GUIScrollBars_GetScrollInfoPos($hGUI, $SB_VERT))
    MemoWrite("nMin.....: " & _GUIScrollBars_GetScrollInfoMin($hGUI, $SB_VERT))
    MemoWrite("nMax.....: " & _GUIScrollBars_GetScrollInfoMax($hGUI, $SB_VERT))
    MemoWrite("nTrackPos: " & _GUIScrollBars_GetScrollInfoTrackPos($hGUI, $SB_VERT))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite