UDF > GUI > GuiScrollBars >

_GUIScrollBars_GetScrollRange

Obtient les positions minimale et maximale actuelles du curseur de défilement d'une barre de défilement spécifié

#include <GuiScrollBars.au3>
_GUIScrollBars_GetScrollRange ( $hWnd, $iBar )

Paramètres

$hWnd Le handle de la fenêtre
$iBar Spécifie le type de barre de défilement. Ce paramètre peut prendre l'une des valeurs suivantes:
    $SB_CTL - Obtient les positions d'un contrôle barre de défilement. Le paramètre $hWnd doit être le handle du contrôle de la barre de défilement.
    $SB_HORZ - Obtient les positions de la barre de défilement horizontale standard de la fenêtre.
    $SB_VERT - Obtient les positions de la barre de défilement verticale standard de la fenêtre.

Valeur de retour

Succès: Retourne les positions minimale et maximale actuelles du bouton de défilement de la barre de défilement spécifié dans le format suivant:
    [0] - position minimale
    [1] - position maximale
Échec: Définit @error <> 0.

En relation

_GUIScrollBars_SetScrollRange

Voir aussi

Consultez GetScrollRange dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiScrollBars.au3>
#include <StructureConstants.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $aRangeMinMax

    $hGUI = GUICreate("ScrollBar Example", 400, 400, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_SIZEBOX))
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 380, 380, BitOR($WS_HSCROLL, $WS_VSCROLL))
    GUICtrlSetResizing($g_idMemo, $GUI_DOCKALL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetBkColor(0x88AABB)

    GUISetState(@SW_SHOW)

    _GUIScrollBars_Init($hGUI)

    $aRangeMinMax = _GUIScrollBars_GetScrollRange($hGUI, $SB_VERT)
    MemoWrite("Vertical Min/Max: " & $aRangeMinMax[0] & "/" & $aRangeMinMax[1])
    $aRangeMinMax = _GUIScrollBars_GetScrollRange($hGUI, $SB_HORZ)
    MemoWrite("Horizontal Min/Max: " & $aRangeMinMax[0] & "/" & $aRangeMinMax[1])
    Sleep(1000)
    _GUIScrollBars_SetScrollRange($hGUI, $SB_VERT, 3, 30)
    $aRangeMinMax = _GUIScrollBars_GetScrollRange($hGUI, $SB_VERT)
    MemoWrite("New Vertical Min/Max: " & $aRangeMinMax[0] & "/" & $aRangeMinMax[1])
    Sleep(1000)
    _GUIScrollBars_SetScrollRange($hGUI, $SB_HORZ, 10, 98)
    $aRangeMinMax = _GUIScrollBars_GetScrollRange($hGUI, $SB_HORZ)
    MemoWrite("New Horizontal Min/Max: " & $aRangeMinMax[0] & "/" & $aRangeMinMax[1])

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Écrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite