UDF > GUI > GuiScrollBars >

_GUIScrollBars_GetScrollPos

Obtient la position instantanée du curseur de défilement d'une barre de défilement spécifiée

#include <GuiScrollBars.au3>
_GUIScrollBars_GetScrollPos ( $hWnd, $iBar )

Paramètres

$hWnd Le handle de la fenêtre
$iBar Spécifie le type de barre de défilement. Ce paramètre peut prendre l'une des valeurs suivantes:
    $SB_CTL - Obtient les positions d'un contrôle barre de défilement. Le paramètre $hWnd doit être le handle du contrôle de la barre de défilement.
    $SB_HORZ - Obtient les positions de la barre de défilement horizontale standard de la fenêtre.
    $SB_VERT - Obtient les positions de la barre de défilement verticale standard de la fenêtre.

Valeur de retour

Succès: Retourne la position instantanée du curseur de défilement.
Échec: Retourne -1.

En relation

_GUIScrollBars_SetScrollInfoPos

Voir aussi

Consultez GetScrollPos dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiScrollBars.au3>
#include <StructureConstants.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI

    $hGUI = GUICreate("ScrollBar Example", 400, 400, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_SIZEBOX))
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 380, 380, BitOR($WS_HSCROLL, $WS_VSCROLL))
    GUICtrlSetResizing($g_idMemo, $GUI_DOCKALL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetBkColor(0x88AABB)

    GUISetState(@SW_SHOW)

    _GUIScrollBars_Init($hGUI)

    _GUIScrollBars_SetScrollInfoPos($hGUI, $SB_HORZ, 10)
    MemoWrite("Scroll Pos Horizontal: " & _GUIScrollBars_GetScrollPos($hGUI, $SB_HORZ))
    Sleep(1000)
    _GUIScrollBars_SetScrollInfoPos($hGUI, $SB_HORZ, 0)
    MemoWrite("Scroll Pos Horizontal: " & _GUIScrollBars_GetScrollPos($hGUI, $SB_HORZ))
    Sleep(1000)
    _GUIScrollBars_SetScrollInfoPos($hGUI, $SB_VERT, 20)
    MemoWrite("Scroll Pos Vertical: " & _GUIScrollBars_GetScrollPos($hGUI, $SB_VERT))
    Sleep(1000)
    _GUIScrollBars_SetScrollInfoPos($hGUI, $SB_VERT, 0)
    MemoWrite("Scroll Pos Vertical: " & _GUIScrollBars_GetScrollPos($hGUI, $SB_VERT))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Écrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite