UDF > GUI > GuiScrollBars >

_GUIScrollBars_GetScrollBarXYLineButton

Obtient la hauteur ou la largeur du curseur de défilement d'une barre de défilement

#include <GuiScrollBars.au3>
_GUIScrollBars_GetScrollBarXYLineButton ( $hWnd, $iObject )

Paramètres

$hWnd Le handle de la fenêtre
$iObject Spécifie l'objet barre de défilement. Ce paramètre peut prendre l'une des valeurs suivantes:
    $OBJID_CLIENT - Le paramètre $hWnd est le handle d'un contrôle barre de défilement.
    $OBJID_HSCROLL - La barre de défilement horizontale de la fenêtre $hWnd.
    $OBJID_VSCROLL - La barre de défilement verticale de la fenêtre $hWnd.

Valeur de retour

Succès: Retourne la hauteur ou la largeur du curseur de défilement.
Échec: Retourne -1 et définit @error <> 0.

En relation

_GUIScrollBars_GetScrollBarInfoEx

Exemple

#include <GUIConstantsEx.au3>
#include <GuiScrollBars.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI

    $hGUI = GUICreate("ScrollBar Example", 400, 400, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_SIZEBOX))
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 380, 360, BitOR($WS_HSCROLL, $WS_VSCROLL))
    GUICtrlSetResizing($g_idMemo, $GUI_DOCKALL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetBkColor(0x88AABB)

    GUISetState(@SW_SHOW)

    _GUIScrollBars_Init($hGUI)

    MemoWrite("Horizontal" & @CRLF & "--------------------------------------")
    MemoWrite("Height of thumb: " & _GUIScrollBars_GetScrollBarXYLineButton($hGUI, $OBJID_HSCROLL) & @CRLF)

    MemoWrite("Vertical" & @CRLF & "--------------------------------------")
    MemoWrite("Width of thumb: " & _GUIScrollBars_GetScrollBarXYLineButton($hGUI, $OBJID_VSCROLL))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite