UDF > GUI > GuiTreeView >

_GUICtrlTreeView_SetItemHeight

Définit la hauteur d'un noeud individuel

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetItemHeight ( $hWnd, $hItem, $iIntegral )

Paramètres

$hWnd ID/handle du contrôle
$hItem Handle du noeud
$iIntegral Hauteur du noeud. Cette hauteur est une incrémentation de la hauteur standard du noeud. Par défaut, chaque
noeud reçoit un incrément égal à la hauteur du noeud. Définir ce champ à 2 donnera au noeud une hauteur double de la hauteur standard;
Définir ce champ à 3 donnera au noeud une hauteur triple de la hauteur standard; et ainsi de suite. Le contrôle n'est pas
dessiné dans cette zone supplémentaire.

Valeur de retour

Succès: Retourne True .
Échec: Retourne False.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $aidItem[6], $idTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Set Item Height", 400, 300)

    $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    For $x = 0 To UBound($aidItem) - 1
        $aidItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x + 1), $idTreeView)
    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    _GUICtrlTreeView_SetItemHeight($idTreeView, $aidItem[2], 2)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example