UDF > GUI > GuiTreeView >

_GUICtrlTreeView_SetCut

Définit si le noeud est dessiné comme s'il était sélectionné dans le cadre d'une opération de copier-coller

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetCut ( $hWnd, $hItem [, $bFlag = True] )

Paramètres

$hWnd ID/handle du contrôle
$hItem Handle du noeud
$bFlag [optionnel] Valeur de l'indicateur:
    True - Le noeud est dessiné comme indiqué plus haut
    False - Le noeud est dessiné normalement

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUICtrlTreeView_GetCut

Exemple

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $aidItem[6], $hRandomItem, $idTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Set Cut", 400, 300)

    $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    For $x = 0 To UBound($aidItem) - 1
        $aidItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x + 1), $idTreeView)
    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    $hRandomItem = Random(0, UBound($aidItem) - 1, 1)
    MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Item %d Cut? %s", $hRandomItem, _GUICtrlTreeView_GetCut($idTreeView, $aidItem[$hRandomItem])))
    _GUICtrlTreeView_SetCut($idTreeView, $aidItem[$hRandomItem])
    MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Item %d Cut? %s", $hRandomItem, _GUICtrlTreeView_GetCut($idTreeView, $aidItem[$hRandomItem])))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example