UDF > GUI > GuiTreeView >


_GUICtrlTreeView_GetPrevSibling

Retourne le noeud, de même niveau, précédent le noeud spécifié

#include <GuiTreeView.au3>
_GUICtrlTreeView_GetPrevSibling ( $hWnd, $hItem )

Paramètres

$hWnd ID/handle du contrôle
$hItem Handle du noeud

Valeur de retour

Succès: Retourne le handle du noeud frère précédent.
Échec: Retourne 0.

En relation

_GUICtrlTreeView_GetNextSibling

Exemple

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $aidItem[10], $hRandItem, $idTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Get Prev Sibling", 400, 300)

    $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    For $x = 0 To 3
        $aidItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $idTreeView)
        For $y = 1 To Random(2, 10, 1)
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Child", $y), $aidItem[$x])
        Next
    Next
    $aidItem[4] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", 4), $idTreeView)
    For $x = 5 To 9
        $aidItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $idTreeView)
        For $y = 1 To Random(2, 10, 1)
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Child", $y), $aidItem[$x])
        Next
    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    $hRandItem = Random(0, 8, 1)
    MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Index %d, Prev: %s", $hRandItem, _GUICtrlTreeView_GetPrevSibling($idTreeView, $aidItem[$hRandItem])))
    _GUICtrlTreeView_SelectItem($idTreeView, _GUICtrlTreeView_GetPrevSibling($idTreeView, $aidItem[$hRandItem]))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example