UDF > GUI > GuiTreeView >

_GUICtrlTreeView_SelectItem

Sélectionne le noeud spécifié, fait défiler l'arbre pour que le noeud soit dans la vue, ou redessine le noeud

#include <GuiTreeView.au3>
_GUICtrlTreeView_SelectItem ( $hWnd, $hItem [, $iFlag = 0] )

Paramètres

$hWnd ID/handle du contrôle
$hItem Handle du noeud
$iFlag [optionnel] Indicateur d'action:
    $TVGN_CARET - Définit la sélection du noeud donné
    $TVGN_DROPHILITE - Redessine le noeud donné dans le style utilisé pour indiquer la cible d'une opération de glisser/déposer
    $TVGN_FIRSTVISIBLE - Fait défiler l'arbre verticalement de sorte que le noeud donné soit le premier noeud visible

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $aidItem[10], $iRand, $idTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS)

    GUICreate("TreeView Select Item", 400, 300)

    $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    For $x = 0 To 9
        $aidItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $idTreeView)
        For $y = 1 To 3
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Child", $y), $aidItem[$x])
        Next
    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    $iRand = Random(0, 9, 1)
    _GUICtrlTreeView_SelectItem($idTreeView, $aidItem[$iRand])

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example