UDF > GUI > GuiTreeView >

_GUICtrlTreeView_GetNext

Retourne le noeud qui suit le noeud spécifié

#include <GuiTreeView.au3>
_GUICtrlTreeView_GetNext ( $hWnd, $hItem )

Paramètres

$hWnd ID/handle du contrôle
$hItem Handle du noeud

Valeur de retour

Succès: Retourne le handle du noeud suivant.
Échec: Retourne 0.

Remarque

Si le noeud spécifié est le dernier noeud, _GUICtrlTreeView_GetNext() renvoie 0, sinon elle retpurne le noeud suivant y compris les noeuds qui ne sont pas visibles et les noeuds enfants.
Pour obtenir le noeud suivant au même niveau que le noeud spécifié, utilisez _GUICtrlTreeView_GetNextSibling() .
Pour obtenir le noeud suivant visible, utilisez _GUICtrlTreeView_GetNextVisible() .

En relation

_GUICtrlTreeView_GetNextSibling, _GUICtrlTreeView_GetNextVisible, _GUICtrlTreeView_GetPrev

Exemple

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $aidItem[10], $idTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Get Next", 400, 300)

    $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    For $x = 0 To 3
        $aidItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x + 1), $idTreeView)
        For $y = 1 To Random(2, 10, 1)
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Child", $y), $aidItem[$x])
        Next
    Next
    $aidItem[4] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", 5), $idTreeView)
    For $x = 5 To 9
        $aidItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x + 1), $idTreeView)
        For $y = 1 To Random(2, 10, 1)
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Child", $y), $aidItem[$x])
        Next
    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    MsgBox($MB_SYSTEMMODAL, "Information", "Index 2, Next: " & _GUICtrlTreeView_GetNext($idTreeView, $aidItem[2]))
    _GUICtrlTreeView_SelectItem($idTreeView, _GUICtrlTreeView_GetNext($idTreeView, $aidItem[2]))

    MsgBox($MB_SYSTEMMODAL, "Information", "Index 4, Next: " & _GUICtrlTreeView_GetNext($idTreeView, $aidItem[4]))
    _GUICtrlTreeView_SelectItem($idTreeView, _GUICtrlTreeView_GetNext($idTreeView, $aidItem[4]))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example