UDF > GUI > GuiToolbar >


_GUICtrlToolbar_LoadImages

Charge les images de bouton, définies par le système, dans la liste d'images d'une barre d'outils

#include <GuiToolbar.au3>
_GUICtrlToolbar_LoadImages ( $hWnd, $iBitMapID )

Paramètres

$hWnd Handle du contrôle barre d'outils
$iBitMapID Identifiant d'une liste d'images de bouton définie par le système. Peut prendre une des valeurs suivantes:
    $IDB_HIST_LARGE_COLOR
    $IDB_HIST_SMALL_COLOR
    $IDB_STD_LARGE_COLOR
    $IDB_STD_SMALL_COLOR
    $IDB_VIEW_LARGE_COLOR
    $IDB_VIEW_SMALL_COLOR
    $IDB_HIST_NORMAL
    $IDB_HIST_HOT
    $IDB_HIST_DISABLED
    $IDB_HIST_PRESSED

Valeur de retour

Succès: Retourne le nombre d'images dans la liste des images, non compris celle que vous venez d'ajouter.
Échec: Retourne 0.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGUI, $hToolbar, $aStrings[4]
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    ; Crée une GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    GUISetState(@SW_SHOW)

    ; Ajoute des bitmaps système standards
    _GUICtrlToolbar_SetBitmapSize($hToolbar, 24, 24)
    _GUICtrlToolbar_LoadImages($hToolbar, $IDB_STD_LARGE_COLOR)

    ; Ajoute des chaînes
    $aStrings[0] = _GUICtrlToolbar_AddString($hToolbar, "&New Button")
    $aStrings[1] = _GUICtrlToolbar_AddString($hToolbar, "&Open Button")
    $aStrings[2] = _GUICtrlToolbar_AddString($hToolbar, "&Save Button")
    $aStrings[3] = _GUICtrlToolbar_AddString($hToolbar, "&Help Button")

    ; Ajoute des boutons
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW, $aStrings[0])
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN, $aStrings[1])
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE, $aStrings[2])
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP, $aStrings[3])

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example