UDF > GUI > GuiToolbar >

_GUICtrlToolbar_CheckButton

Coche ou décoche un bouton donné

#include <GuiToolbar.au3>
_GUICtrlToolbar_CheckButton ( $hWnd, $iCommandID [, $bCheck = True] )

Paramètres

$hWnd Handle du contrôle barre d'outils
$iCommandID ID de la commande relative au bouton
$bCheck [optionnel] État à donner au bouton:
    True - Le bouton sera coché
    False - Le bouton sera décoché

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarque

Quand un bouton est cochée, il est affiché dans l'état pressé

Exemple

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGUI, $hToolbar
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    ; Create GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    GUISetState(@SW_SHOW)

    ; Add standard system bitmaps
    _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)

    ; Add buttons
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Check Save button
    _GUICtrlToolbar_CheckButton($hToolbar, $e_idSave)

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example