UDF > GUI > GuiTab >

_GUICtrlTab_SetItemState

Définit l'état d'un onglet

#include <GuiTab.au3>
_GUICtrlTab_SetItemState ( $hWnd, $iIndex, $iState )

Paramètres

$hWnd ID/handle du contrôle Tab
$iIndex Index, de base 0, de l'onglet
$iState État de l'onglet. Il peut s'agir d'une combinaison de:
    $TCIS_BUTTONPRESSED - L'onglet du contrôle est sélectionné
    $TCIS_HIGHLIGHTED - L'onglet du contrôle est en surbrillance

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUICtrlTab_GetItemState

Exemple

#include <GUIConstantsEx.au3>
#include <GuiTab.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idTab

    ; Crée une GUI
    GUICreate("Tab Control Set Item State", 400, 300)
    $idTab = GUICtrlCreateTab(2, 2, 396, 296, $TCS_BUTTONS)
    GUISetState(@SW_SHOW)

    ; Ajoute des onglets
    _GUICtrlTab_InsertItem($idTab, 0, "Tab 1")
    _GUICtrlTab_InsertItem($idTab, 1, "Tab 2")
    _GUICtrlTab_InsertItem($idTab, 2, "Tab 3")

    ; Obtient/Définit l'état de l'onglet 2
    _GUICtrlTab_SetItemState($idTab, 1, $TCIS_BUTTONPRESSED)
    MsgBox($MB_SYSTEMMODAL, "Information", "Tab 2 state: " & _ExplainItemState(_GUICtrlTab_GetItemState($idTab, 1)))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

Func _ExplainItemState($iState)
    Local $sText = ""
    If $iState = 0 Then $sText &= "Aucun état défini sur cet onglet" & @CRLF
    If BitAND($iState, 1) Then $sText &= "Bouton pressé" & @CRLF
    If BitAND($iState, 2) Then $sText &= "Bouton en surbrillance"
    Return $sText
EndFunc   ;==>_ExplainItemState