UDF > GUI > GuiTab >

_GUICtrlTab_SetCurFocus

Définit le focus sur un onglet spécifié

#include <GuiTab.au3>
_GUICtrlTab_SetCurFocus ( $hWnd, $iIndex )

Paramètres

$hWnd ID/handle du contrôle Tab
$iIndex Index, de base 0, de l'onglet

Valeur de retour

Aucune.

Remarques

Si le contrôle à onglet a le style $TCS_BUTTONS (mode bouton), l'onglet qui reçoit le focus peut être différent de l'onglet sélectionné.
Par exemple, quand un onglet est sélectionné, l'utilisateur peut appuyer sur les touches fléchées pour définir le focus sur un onglet différent sans changer l'onglet sélectionné.
En mode bouton, $TCM_SETCURFOCUS définit le focus d'entrée au bouton associé à l'onglet spécifié, mais il ne change pas l'onglet sélectionné.

Si le contrôle onglet n'a pas le style $TCS_BUTTONS, le changement du focus change aussi l'onglet sélectionné.

En relation

_GUICtrlTab_GetCurFocus

Exemple

#include <GUIConstantsEx.au3>
#include <GuiTab.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idTab

    ; Crée une GUI
    GUICreate("Tab Control Set Current Focus", 400, 300)
    $idTab = GUICtrlCreateTab(2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Ajoute des onglets
    _GUICtrlTab_InsertItem($idTab, 0, "Tab 1")
    _GUICtrlTab_InsertItem($idTab, 1, "Tab 2")
    _GUICtrlTab_InsertItem($idTab, 2, "Tab 3")

    ; Obtient/Définit le focus en cours
    _GUICtrlTab_SetCurFocus($idTab, 1)
    MsgBox($MB_SYSTEMMODAL, "Information", "Current Focus: " & _GUICtrlTab_GetCurFocus($idTab))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example