#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiTab.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIGdi.au3>

Example()

Func Example()
    Local $hGUI, $hImage, $hTab

    ; Crée une GUI
    $hGUI = GUICreate("Tab Control Get Image List", 400, 300)
    $hTab = _GUICtrlTab_Create($hGUI, 2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Crée des images
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 16, 16))
    _GUICtrlTab_SetImageList($hTab, $hImage)

    ; Ajoute des onglets
    _GUICtrlTab_InsertItem($hTab, 0, "Tab 1", 0)
    _GUICtrlTab_InsertItem($hTab, 1, "Tab 2", 1)
    _GUICtrlTab_InsertItem($hTab, 2, "Tab 3", 2)

    ; Affiche le handle de la liste d'images
    MsgBox($MB_SYSTEMMODAL, "Information", "Image list handle: 0x" & Hex(_GUICtrlTab_GetImageList($hTab)) & @CRLF & _
            "IsPtr = " & IsPtr(_GUICtrlTab_GetImageList($hTab)) & " IsHWnd = " & IsHWnd(_GUICtrlTab_GetImageList($hTab)))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example