UDF > GUI > GuiTab >

_GUICtrlTab_GetDisplayRectEx

Obtient le rectangle d'affichage de la zone client client (type structure)

#include <GuiTab.au3>
_GUICtrlTab_GetDisplayRectEx ( $hWnd )

Paramètre

$hWnd Handle du contrôle

Valeur de retour

Retourne une structure $tagRECT qui reçoit le rectangle de l'onglet, en coordonnées viewport.

Remarque

Utilisez cette fonction pour obtenir les coordonnées, en pixels, de la zone du contrôle à onglet qui représente le contenu des onglets.
L'apparence de cette partie du contrôle ne change pas lorsque différents onglets sont sélectionnés.

En relation

$tagRECT, _GUICtrlTab_GetDisplayRect

Exemple

#include <GUIConstantsEx.au3>
#include <GuiTab.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $tRECT, $sRect, $idTab

    ; Crée une GUI
    GUICreate("Tab Control Get Display RectEx", 400, 300)
    $idTab = GUICtrlCreateTab(2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Ajoute des onglets
    _GUICtrlTab_InsertItem($idTab, 0, "Tab 1")
    _GUICtrlTab_InsertItem($idTab, 1, "Tab 2")
    _GUICtrlTab_InsertItem($idTab, 2, "Tab 3")

    ; Obtient le rectangle d'affichage
    $tRECT = _GUICtrlTab_GetDisplayRectEx(GUICtrlGetHandle($idTab))
    $sRect = StringFormat("[%d, %d, %d, %d]", DllStructGetData($tRECT, "Left"), _
            DllStructGetData($tRECT, "Top"), _
            DllStructGetData($tRECT, "Right"), _
            DllStructGetData($tRECT, "Bottom"))
    MsgBox($MB_SYSTEMMODAL, "Information", "Display rectangle: " & $sRect)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example