UDF > GUI > GuiStatusBar >

_GUICtrlStatusBar_SetBkColor

Définit la couleur d'arrière-plan

#include <GuiStatusBar.au3>
_GUICtrlStatusBar_SetBkColor ( $hWnd, $iColor )

Paramètres

$hWnd Handle du contrôle StatusBar
$iColor Nouvelle couleur de fond. Spécifiez la valeur CLR_DEFAULT pour que la barre d'état utilise sa couleur de fond par défaut.

Valeur de retour

Retourne la couleur de fond précédente, ou CLR_DEFAULT si la couleur de fond est la couleur par défaut.

Remarques

Retourne une couleur RVB COLORREF, la couleur passée en paramètre doit être BGR Hex ou RVB COLORREF

Les contrôles StatusBar ne peuvent pas être peints si le style "Windows XP" est utilisé. Des thèmes empêchent aussi la statusbar d'être coloré - si la fonction semble défaillante, essayez d'enlever le thème en utilisant _WinAPI_SetWindowTheme() avec des chaînes vides pour paramètres.

Exemple

#include <ColorConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WinAPITheme.au3>

Example()

Func Example()
    Local $hGUI, $hStatus
    Local $aParts[3] = [75, 150, -1]

    ; Crée une GUI
    $hGUI = GUICreate("StatusBar Set BkColor", 400, 300)
    $hStatus = _GUICtrlStatusBar_Create($hGUI)
    GUISetState(@SW_SHOW)

    ; Pour permettre le paramètrage de Bk Color au moins sous Windows 10
    _WinAPI_SetWindowTheme($hStatus, "", "")

    ; Définit des parties
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)
    _GUICtrlStatusBar_SetText($hStatus, "Part 1")
    _GUICtrlStatusBar_SetText($hStatus, "Part 2", 1)
    _GUICtrlStatusBar_SetText($hStatus, "Part 3", 2)

    ; Définit la couleur d'arrière-plan
    _GUICtrlStatusBar_SetBkColor($hStatus, $CLR_MONEYGREEN)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example