UDF > GUI > GuiStatusBar >

_GUICtrlStatusBar_GetRectEx

Obtient, dans une structure, le rectangle englobant une partie

#include <GuiStatusBar.au3>
_GUICtrlStatusBar_GetRectEx ( $hWnd, $iPart )

Paramètres

$hWnd Handle du contrôle StatusBar
$iPart Index, de base 0, de la partie.
Si le contrôle est en mode simple ce champ est ignoré et le rectangle englobant la barre d'état est retourné.

Valeur de retour

Succès: Retourne $tagRECT, une structure qui reçoit le rectangle de délimitation de la partie.
Échec: Définit @error <> 0.

En relation

$tagRECT, _GUICtrlStatusBar_GetRect

Exemple

#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $tRECT, $hStatus
    Local $aParts[3] = [75, 150, -1]

    ; Crée une GUI
    $hGUI = GUICreate("StatusBar Get RectEx", 400, 300)
    $hStatus = _GUICtrlStatusBar_Create($hGUI)

    ; Crée un contrôle memo
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Définit/Obtient des parties
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)

    ; Obtient le rectangle de la partie 1
    $tRECT = _GUICtrlStatusBar_GetRectEx($hStatus, 0)
    MemoWrite("Part 1 left ...: " & DllStructGetData($tRECT, "Left"))
    MemoWrite("Part 1 top ....: " & DllStructGetData($tRECT, "Top"))
    MemoWrite("Part 1 right ..: " & DllStructGetData($tRECT, "Right"))
    MemoWrite("Part 1 bottom .: " & DllStructGetData($tRECT, "Bottom"))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Ecrit un message dans le contrôle memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite